sys/platform/pc32/i386/swtch.s

   1 /*
   2  * Copyright (c) 2003,2004 The DragonFly Project.  All rights reserved.
   3  *
   4  * This code is derived from software contributed to The DragonFly Project
   5  * by Matthew Dillon <dillon@backplane.com>
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  *
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in
  15  *    the documentation and/or other materials provided with the
  16  *    distribution.
  17  * 3. Neither the name of The DragonFly Project nor the names of its
  18  *    contributors may be used to endorse or promote products derived
  19  *    from this software without specific, prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  22  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  23  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  24  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  25  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  26  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  27  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  28  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  29  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  30  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  31  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  * Copyright (c) 1990 The Regents of the University of California.
  35  * All rights reserved.
  36  *
  37  * This code is derived from software contributed to Berkeley by
  38  * William Jolitz.
  39  *
  40  * Redistribution and use in source and binary forms, with or without
  41  * modification, are permitted provided that the following conditions
  42  * are met:
  43  * 1. Redistributions of source code must retain the above copyright
  44  *    notice, this list of conditions and the following disclaimer.
  45  * 2. Redistributions in binary form must reproduce the above copyright
  46  *    notice, this list of conditions and the following disclaimer in the
  47  *    documentation and/or other materials provided with the distribution.
  48  * 3. All advertising materials mentioning features or use of this software
  49  *    must display the following acknowledgement:
  50  *      This product includes software developed by the University of
  51  *      California, Berkeley and its contributors.
  52  * 4. Neither the name of the University nor the names of its contributors
  53  *    may be used to endorse or promote products derived from this software
  54  *    without specific prior written permission.
  55  *
  56  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  57  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  58  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  59  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  60  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  61  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  62  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  63  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  64  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  65  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  66  * SUCH DAMAGE.
  67  *
  68  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
  69  * $DragonFly: src/sys/platform/pc32/i386/swtch.s,v 1.42 2006/11/07 18:50:07 dillon Exp $
  70  */
  71
  72 #include "use_npx.h"
  73
  74 #include <sys/rtprio.h>
  75
  76 #include <machine/asmacros.h>
  77 #include <machine/segments.h>
  78
  79 #include <machine/pmap.h>
  80 #include <machine_base/apic/apicreg.h>
  81 #include <machine/lock.h>
  82
  83 #include "assym.s"
  84
  85 #if defined(SMP)
  86 #define MPLOCKED        lock ;
  87 #else
  88 #define MPLOCKED
  89 #endif
  90
  91         .data
  92
  93         .globl  panic
  94
  95 #if defined(SWTCH_OPTIM_STATS)
  96         .globl  swtch_optim_stats, tlb_flush_count
  97 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
  98 tlb_flush_count:        .long   0
  99 #endif
 100
 101         .text
 102
 103
 104 /*
 105  * cpu_heavy_switch(next_thread)
 106  *
 107  *      Switch from the current thread to a new thread.  This entry
 108  *      is normally called via the thread->td_switch function, and will
 109  *      only be called when the current thread is a heavy weight process.
 110  *
 111  *      Some instructions have been reordered to reduce pipeline stalls.
 112  *
 113  *      YYY disable interrupts once giant is removed.
 114  */
 115 ENTRY(cpu_heavy_switch)
 116         /*
 117          * Save general regs
 118          */
 119         movl    PCPU(curthread),%ecx
 120         movl    (%esp),%eax                     /* (reorder optimization) */
 121         movl    TD_PCB(%ecx),%edx               /* EDX = PCB */
 122         movl    %eax,PCB_EIP(%edx)              /* return PC may be modified */
 123         movl    %ebx,PCB_EBX(%edx)
 124         movl    %esp,PCB_ESP(%edx)
 125         movl    %ebp,PCB_EBP(%edx)
 126         movl    %esi,PCB_ESI(%edx)
 127         movl    %edi,PCB_EDI(%edx)
 128         movl    %gs,PCB_GS(%edx)
 129
 130         movl    %ecx,%ebx                       /* EBX = curthread */
 131         movl    TD_PROC(%ecx),%ecx
 132         movl    PCPU(cpuid), %eax
 133         movl    P_VMSPACE(%ecx), %ecx           /* ECX = vmspace */
 134         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%ecx)
 135
 136         /*
 137          * Push the LWKT switch restore function, which resumes a heavy
 138          * weight process.  Note that the LWKT switcher is based on
 139          * TD_SP, while the heavy weight process switcher is based on
 140          * PCB_ESP.  TD_SP is usually two ints pushed relative to
 141          * PCB_ESP.  We push the flags for later restore by cpu_heavy_restore.
 142          */
 143         pushfl
 144         pushl   $cpu_heavy_restore
 145         movl    %esp,TD_SP(%ebx)
 146
 147         /*
 148          * Save debug regs if necessary
 149          */
 150         movb    PCB_FLAGS(%edx),%al
 151         andb    $PCB_DBREGS,%al
 152         jz      1f                              /* no, skip over */
 153         movl    %dr7,%eax                       /* yes, do the save */
 154         movl    %eax,PCB_DR7(%edx)
 155         andl    $0x0000fc00, %eax               /* disable all watchpoints */
 156         movl    %eax,%dr7
 157         movl    %dr6,%eax
 158         movl    %eax,PCB_DR6(%edx)
 159         movl    %dr3,%eax
 160         movl    %eax,PCB_DR3(%edx)
 161         movl    %dr2,%eax
 162         movl    %eax,PCB_DR2(%edx)
 163         movl    %dr1,%eax
 164         movl    %eax,PCB_DR1(%edx)
 165         movl    %dr0,%eax
 166         movl    %eax,PCB_DR0(%edx)
 167 1:
 168
 169 #if NNPX > 0
 170         /*
 171          * Save the FP state if we have used the FP.  Note that calling
 172          * npxsave will NULL out PCPU(npxthread).
 173          */
 174         cmpl    %ebx,PCPU(npxthread)
 175         jne     1f
 176         pushl   TD_SAVEFPU(%ebx)
 177         call    npxsave                 /* do it in a big C function */
 178         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 179 1:
 180 #endif  /* NNPX > 0 */
 181
 182         /*
 183          * Switch to the next thread, which was passed as an argument
 184          * to cpu_heavy_switch().  Due to the eflags and switch-restore
 185          * function we pushed, the argument is at 12(%esp).  Set the current
 186          * thread, load the stack pointer, and 'ret' into the switch-restore
 187          * function.
 188          *
 189          * The switch restore function expects the new thread to be in %eax
 190          * and the old one to be in %ebx.
 191          *
 192          * There is a one-instruction window where curthread is the new
 193          * thread but %esp still points to the old thread's stack, but
 194          * we are protected by a critical section so it is ok.
 195          */
 196         movl    12(%esp),%eax           /* EAX = newtd, EBX = oldtd */
 197         movl    %eax,PCPU(curthread)
 198         movl    TD_SP(%eax),%esp
 199         ret
 200
 201 /*
 202  *  cpu_exit_switch()
 203  *
 204  *      The switch function is changed to this when a thread is going away
 205  *      for good.  We have to ensure that the MMU state is not cached, and
 206  *      we don't bother saving the existing thread state before switching.
 207  *
 208  *      At this point we are in a critical section and this cpu owns the
 209  *      thread's token, which serves as an interlock until the switchout is
 210  *      complete.
 211  */
 212 ENTRY(cpu_exit_switch)
 213         /*
 214          * Get us out of the vmspace
 215          */
 216         movl    IdlePTD,%ecx
 217         movl    %cr3,%eax
 218         cmpl    %ecx,%eax
 219         je      1f
 220         movl    %ecx,%cr3
 221 1:
 222         movl    PCPU(curthread),%ebx
 223         /*
 224          * Switch to the next thread.  RET into the restore function, which
 225          * expects the new thread in EAX and the old in EBX.
 226          *
 227          * There is a one-instruction window where curthread is the new
 228          * thread but %esp still points to the old thread's stack, but
 229          * we are protected by a critical section so it is ok.
 230          */
 231         movl    4(%esp),%eax
 232         movl    %eax,PCPU(curthread)
 233         movl    TD_SP(%eax),%esp
 234         ret
 235
 236 /*
 237  * cpu_heavy_restore()  (current thread in %eax on entry)
 238  *
 239  *      Restore the thread after an LWKT switch.  This entry is normally
 240  *      called via the LWKT switch restore function, which was pulled
 241  *      off the thread stack and jumped to.
 242  *
 243  *      This entry is only called if the thread was previously saved
 244  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
 245  *      or when a new process is initially scheduled.  The first thing we
 246  *      do is clear the TDF_RUNNING bit in the old thread and set it in the
 247  *      new thread.
 248  *
 249  *      NOTE: The process may be in any state, not necessarily SRUN, because
 250  *      a preemption switch may interrupt the process and then return via
 251  *      cpu_heavy_restore.
 252  *
 253  *      YYY theoretically we do not have to restore everything here, a lot
 254  *      of this junk can wait until we return to usermode.  But for now
 255  *      we restore everything.
 256  *
 257  *      YYY the PCB crap is really crap, it makes startup a bitch because
 258  *      we can't switch away.
 259  *
 260  *      YYY note: spl check is done in mi_switch when it splx()'s.
 261  */
 262
 263 ENTRY(cpu_heavy_restore)
 264         popfl
 265         movl    TD_PCB(%eax),%edx               /* EDX = PCB */
 266         movl    TD_PROC(%eax),%ecx
 267
 268 #if defined(SWTCH_OPTIM_STATS)
 269         incl    _swtch_optim_stats
 270 #endif
 271         /*
 272          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
 273          * safely test/reload %cr3 until after we have set the bit in the
 274          * pmap (remember, we do not hold the MP lock in the switch code).
 275          */
 276         movl    P_VMSPACE(%ecx), %ecx           /* ECX = vmspace */
 277         movl    PCPU(cpuid), %esi
 278         MPLOCKED btsl   %esi, VM_PMAP+PM_ACTIVE(%ecx)
 279
 280         /*
 281          * Restore the MMU address space.  If it is the same as the last
 282          * thread we don't have to invalidate the tlb (i.e. reload cr3).
 283          * YYY which naturally also means that the PM_ACTIVE bit had better
 284          * already have been set before we set it above, check? YYY
 285          */
 286         movl    %cr3,%esi
 287         movl    PCB_CR3(%edx),%ecx
 288         cmpl    %esi,%ecx
 289         je      4f
 290 #if defined(SWTCH_OPTIM_STATS)
 291         decl    _swtch_optim_stats
 292         incl    _tlb_flush_count
 293 #endif
 294         movl    %ecx,%cr3
 295 4:
 296         /*
 297          * Clear TDF_RUNNING flag in old thread only after cleaning up
 298          * %cr3.  The target thread is already protected by being TDF_RUNQ
 299          * so setting TDF_RUNNING isn't as big a deal.
 300          */
 301         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 302         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 303
 304         /*
 305          * Deal with the PCB extension, restore the private tss
 306          */
 307         movl    PCB_EXT(%edx),%edi      /* check for a PCB extension */
 308         movl    $1,%ebx                 /* maybe mark use of a private tss */
 309         testl   %edi,%edi
 310         jnz     2f
 311
 312         /*
 313          * Going back to the common_tss.  We may need to update TSS_ESP0
 314          * which sets the top of the supervisor stack when entering from
 315          * usermode.  The PCB is at the top of the stack but we need another
 316          * 16 bytes to take vm86 into account.
 317          */
 318         leal    -16(%edx),%ebx
 319         movl    %ebx, PCPU(common_tss) + TSS_ESP0
 320
 321         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
 322         je      3f                      /* already using the common TSS */
 323
 324         subl    %ebx,%ebx               /* unmark use of private tss */
 325
 326         /*
 327          * Get the address of the common TSS descriptor for the ltr.
 328          * There is no way to get the address of a segment-accessed variable
 329          * so we store a self-referential pointer at the base of the per-cpu
 330          * data area and add the appropriate offset.
 331          */
 332         movl    $gd_common_tssd, %edi
 333         addl    %fs:0, %edi
 334
 335         /*
 336          * Move the correct TSS descriptor into the GDT slot, then reload
 337          * ltr.
 338          */
 339 2:
 340         movl    %ebx,PCPU(private_tss)          /* mark/unmark private tss */
 341         movl    PCPU(tss_gdt), %ebx             /* entry in GDT */
 342         movl    0(%edi), %eax
 343         movl    %eax, 0(%ebx)
 344         movl    4(%edi), %eax
 345         movl    %eax, 4(%ebx)
 346         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
 347         ltr     %si
 348
 349 3:
 350         /*
 351          * Restore general registers.
 352          */
 353         movl    PCB_EBX(%edx),%ebx
 354         movl    PCB_ESP(%edx),%esp
 355         movl    PCB_EBP(%edx),%ebp
 356         movl    PCB_ESI(%edx),%esi
 357         movl    PCB_EDI(%edx),%edi
 358         movl    PCB_EIP(%edx),%eax
 359         movl    %eax,(%esp)
 360
 361         /*
 362          * Restore the user LDT if we have one
 363          */
 364         cmpl    $0, PCB_USERLDT(%edx)
 365         jnz     1f
 366         movl    _default_ldt,%eax
 367         cmpl    PCPU(currentldt),%eax
 368         je      2f
 369         lldt    _default_ldt
 370         movl    %eax,PCPU(currentldt)
 371         jmp     2f
 372 1:      pushl   %edx
 373         call    set_user_ldt
 374         popl    %edx
 375 2:
 376         /*
 377          * Restore the user TLS if we have one
 378          */
 379         pushl   %edx
 380         call    set_user_TLS
 381         popl    %edx
 382         /*
 383          * Restore the %gs segment register, which must be done after
 384          * loading the user LDT.  Since user processes can modify the
 385          * register via procfs, this may result in a fault which is
 386          * detected by checking the fault address against cpu_switch_load_gs
 387          * in i386/i386/trap.c
 388          */
 389         .globl  cpu_switch_load_gs
 390 cpu_switch_load_gs:
 391         movl    PCB_GS(%edx),%gs
 392
 393         /*
 394          * Restore the DEBUG register state if necessary.
 395          */
 396         movb    PCB_FLAGS(%edx),%al
 397         andb    $PCB_DBREGS,%al
 398         jz      1f                              /* no, skip over */
 399         movl    PCB_DR6(%edx),%eax              /* yes, do the restore */
 400         movl    %eax,%dr6
 401         movl    PCB_DR3(%edx),%eax
 402         movl    %eax,%dr3
 403         movl    PCB_DR2(%edx),%eax
 404         movl    %eax,%dr2
 405         movl    PCB_DR1(%edx),%eax
 406         movl    %eax,%dr1
 407         movl    PCB_DR0(%edx),%eax
 408         movl    %eax,%dr0
 409         movl    %dr7,%eax                /* load dr7 so as not to disturb */
 410         andl    $0x0000fc00,%eax         /*   reserved bits               */
 411         pushl   %ebx
 412         movl    PCB_DR7(%edx),%ebx
 413         andl    $~0x0000fc00,%ebx
 414         orl     %ebx,%eax
 415         popl    %ebx
 416         movl    %eax,%dr7
 417 1:
 418
 419         ret
 420
 421 /*
 422  * savectx(pcb)
 423  *
 424  * Update pcb, saving current processor state.
 425  */
 426 ENTRY(savectx)
 427         /* fetch PCB */
 428         movl    4(%esp),%ecx
 429
 430         /* caller's return address - child won't execute this routine */
 431         movl    (%esp),%eax
 432         movl    %eax,PCB_EIP(%ecx)
 433
 434         movl    %cr3,%eax
 435         movl    %eax,PCB_CR3(%ecx)
 436
 437         movl    %ebx,PCB_EBX(%ecx)
 438         movl    %esp,PCB_ESP(%ecx)
 439         movl    %ebp,PCB_EBP(%ecx)
 440         movl    %esi,PCB_ESI(%ecx)
 441         movl    %edi,PCB_EDI(%ecx)
 442         movl    %gs,PCB_GS(%ecx)
 443
 444 #if NNPX > 0
 445         /*
 446          * If npxthread == NULL, then the npx h/w state is irrelevant and the
 447          * state had better already be in the pcb.  This is true for forks
 448          * but not for dumps (the old book-keeping with FP flags in the pcb
 449          * always lost for dumps because the dump pcb has 0 flags).
 450          *
 451          * If npxthread != NULL, then we have to save the npx h/w state to
 452          * npxthread's pcb and copy it to the requested pcb, or save to the
 453          * requested pcb and reload.  Copying is easier because we would
 454          * have to handle h/w bugs for reloading.  We used to lose the
 455          * parent's npx state for forks by forgetting to reload.
 456          */
 457         movl    PCPU(npxthread),%eax
 458         testl   %eax,%eax
 459         je      1f
 460
 461         pushl   %ecx                    /* target pcb */
 462         movl    TD_SAVEFPU(%eax),%eax   /* originating savefpu area */
 463         pushl   %eax
 464
 465         pushl   %eax
 466         call    npxsave
 467         addl    $4,%esp
 468
 469         popl    %eax
 470         popl    %ecx
 471
 472         pushl   $PCB_SAVEFPU_SIZE
 473         leal    PCB_SAVEFPU(%ecx),%ecx
 474         pushl   %ecx
 475         pushl   %eax
 476         call    bcopy
 477         addl    $12,%esp
 478 #endif  /* NNPX > 0 */
 479
 480 1:
 481         ret
 482
 483 /*
 484  * cpu_idle_restore()   (current thread in %eax on entry) (one-time execution)
 485  *
 486  *      Don't bother setting up any regs other then %ebp so backtraces
 487  *      don't die.  This restore function is used to bootstrap into the
 488  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
 489  *      switching.
 490  *
 491  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
 492  *
 493  *      If we are an AP we have to call ap_init() before jumping to
 494  *      cpu_idle().  ap_init() will synchronize with the BP and finish
 495  *      setting up various ncpu-dependant globaldata fields.  This may
 496  *      happen on UP as well as SMP if we happen to be simulating multiple
 497  *      cpus.
 498  */
 499 ENTRY(cpu_idle_restore)
 500         /* cli */
 501         movl    IdlePTD,%ecx
 502         movl    $0,%ebp
 503         pushl   $0
 504         movl    %ecx,%cr3
 505         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 506         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 507 #ifdef SMP
 508         cmpl    $0,PCPU(cpuid)
 509         je      1f
 510         call    ap_init
 511 1:
 512 #endif
 513         sti
 514         jmp     cpu_idle
 515
 516 /*
 517  * cpu_kthread_restore() (current thread is %eax on entry) (one-time execution)
 518  *
 519  *      Don't bother setting up any regs other then %ebp so backtraces
 520  *      don't die.  This restore function is used to bootstrap into an
 521  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
 522  *      after this.
 523  *
 524  *      Since all of our context is on the stack we are reentrant and
 525  *      we can release our critical section and enable interrupts early.
 526  */
 527 ENTRY(cpu_kthread_restore)
 528         sti
 529         movl    IdlePTD,%ecx
 530         movl    TD_PCB(%eax),%edx
 531         movl    $0,%ebp
 532         movl    %ecx,%cr3
 533         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 534         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 535         subl    $TDPRI_CRIT,TD_PRI(%eax)
 536         popl    %eax            /* kthread exit function */
 537         pushl   PCB_EBX(%edx)   /* argument to ESI function */
 538         pushl   %eax            /* set exit func as return address */
 539         movl    PCB_ESI(%edx),%eax
 540         jmp     *%eax
 541
 542 /*
 543  * cpu_lwkt_switch()
 544  *
 545  *      Standard LWKT switching function.  Only non-scratch registers are
 546  *      saved and we don't bother with the MMU state or anything else.
 547  *
 548  *      This function is always called while in a critical section.
 549  *
 550  *      There is a one-instruction window where curthread is the new
 551  *      thread but %esp still points to the old thread's stack, but
 552  *      we are protected by a critical section so it is ok.
 553  *
 554  *      YYY BGL, SPL
 555  */
 556 ENTRY(cpu_lwkt_switch)
 557         pushl   %ebp    /* note: GDB hacked to locate ebp relative to td_sp */
 558         pushl   %ebx
 559         movl    PCPU(curthread),%ebx
 560         pushl   %esi
 561         pushl   %edi
 562         pushfl
 563         /* warning: adjust movl into %eax below if you change the pushes */
 564
 565 #if NNPX > 0
 566         /*
 567          * Save the FP state if we have used the FP.  Note that calling
 568          * npxsave will NULL out PCPU(npxthread).
 569          *
 570          * We have to deal with the FP state for LWKT threads in case they
 571          * happen to get preempted or block while doing an optimized
 572          * bzero/bcopy/memcpy.
 573          */
 574         cmpl    %ebx,PCPU(npxthread)
 575         jne     1f
 576         pushl   TD_SAVEFPU(%ebx)
 577         call    npxsave                 /* do it in a big C function */
 578         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 579 1:
 580 #endif  /* NNPX > 0 */
 581
 582         movl    4+20(%esp),%eax         /* switch to this thread */
 583         pushl   $cpu_lwkt_restore
 584         movl    %esp,TD_SP(%ebx)
 585         movl    %eax,PCPU(curthread)
 586         movl    TD_SP(%eax),%esp
 587
 588         /*
 589          * eax contains new thread, ebx contains old thread.
 590          */
 591         ret
 592
 593 /*
 594  * cpu_lwkt_restore()   (current thread in %eax on entry)
 595  *
 596  *      Standard LWKT restore function.  This function is always called
 597  *      while in a critical section.
 598  *
 599  *      Warning: due to preemption the restore function can be used to
 600  *      'return' to the original thread.  Interrupt disablement must be
 601  *      protected through the switch so we cannot run splz here.
 602  *
 603  *      YYY we theoretically do not need to load IdlePTD into cr3, but if
 604  *      so we need a way to detect when the PTD we are using is being
 605  *      deleted due to a process exiting.
 606  */
 607 ENTRY(cpu_lwkt_restore)
 608         movl    IdlePTD,%ecx    /* YYY borrow but beware desched/cpuchg/exit */
 609         movl    %cr3,%edx
 610         cmpl    %ecx,%edx
 611         je      1f
 612         movl    %ecx,%cr3
 613 1:
 614         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 615         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 616         popfl
 617         popl    %edi
 618         popl    %esi
 619         popl    %ebx
 620         popl    %ebp
 621         ret
 622