contrib/gcc-5.0/libbacktrace/configure.ac

   1 # configure.ac -- Backtrace configure script.
   2 # Copyright (C) 2012-2015 Free Software Foundation, Inc.
   3
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7
   8 #     (1) Redistributions of source code must retain the above copyright
   9 #     notice, this list of conditions and the following disclaimer.
  10
  11 #     (2) Redistributions in binary form must reproduce the above copyright
  12 #     notice, this list of conditions and the following disclaimer in
  13 #     the documentation and/or other materials provided with the
  14 #     distribution.
  15
  16 #     (3) The name of the author may not be used to
  17 #     endorse or promote products derived from this software without
  18 #     specific prior written permission.
  19
  20 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  21 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  22 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  23 # DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT,
  24 # INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  25 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  26 # SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  28 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
  29 # IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30 # POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.64)
  33 AC_INIT(package-unused, version-unused,, libbacktrace)
  34 AC_CONFIG_SRCDIR(backtrace.h)
  35 AC_CONFIG_HEADER(config.h)
  36
  37 if test -n "${with_target_subdir}"; then
  38   AM_ENABLE_MULTILIB(, ..)
  39 fi
  40
  41 AC_CANONICAL_SYSTEM
  42 target_alias=${target_alias-$host_alias}
  43
  44 AC_USE_SYSTEM_EXTENSIONS
  45
  46 libtool_VERSION=1:0:0
  47 AC_SUBST(libtool_VERSION)
  48
  49 # 1.11.1: Require that version of automake.
  50 # foreign: Don't require README, INSTALL, NEWS, etc.
  51 # no-define: Don't define PACKAGE and VERSION.
  52 # no-dependencies: Don't generate automatic dependencies.
  53 #    (because it breaks when using bootstrap-lean, since some of the
  54 #    headers are gone at "make install" time).
  55 # -Wall: Issue all automake warnings.
  56 # -Wno-portability: Don't warn about constructs supported by GNU make.
  57 #    (because GCC requires GNU make anyhow).
  58 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist no-define no-dependencies -Wall -Wno-portability])
  59
  60 AM_MAINTAINER_MODE
  61
  62 AC_ARG_WITH(target-subdir,
  63 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  64
  65 # We must force CC to /not/ be precious variables; otherwise
  66 # the wrong, non-multilib-adjusted value will be used in multilibs.
  67 # As a side effect, we have to subst CFLAGS ourselves.
  68 m4_rename([_AC_ARG_VAR_PRECIOUS],[backtrace_PRECIOUS])
  69 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  70 AC_PROG_CC
  71 m4_rename_force([backtrace_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  72
  73 AC_SUBST(CFLAGS)
  74
  75 AC_PROG_RANLIB
  76
  77 AC_PROG_AWK
  78 case "$AWK" in
  79 "") AC_MSG_ERROR([can't build without awk]) ;;
  80 esac
  81
  82 LT_INIT([disable-shared])
  83 AM_PROG_LIBTOOL
  84
  85 backtrace_supported=yes
  86
  87 if test -n "${with_target_subdir}"; then
  88   # We are compiling a GCC library.  We can assume that the unwind
  89   # library exists.
  90   BACKTRACE_FILE="backtrace.lo simple.lo"
  91 else
  92   AC_CHECK_HEADER([unwind.h],
  93     [AC_CHECK_FUNC([_Unwind_Backtrace],
  94                    [BACKTRACE_FILE="backtrace.lo simple.lo"],
  95                    [BACKTRACE_FILE="nounwind.lo"
  96                     backtrace_supported=no])],
  97     [BACKTRACE_FILE="nounwind.lo"
  98      backtrace_supported=no])
  99 fi
 100 AC_SUBST(BACKTRACE_FILE)
 101
 102 EXTRA_FLAGS=
 103 if test -n "${with_target_subdir}"; then
 104   EXTRA_FLAGS="-funwind-tables -frandom-seed=\$@"
 105 else
 106   AC_CACHE_CHECK([for -funwind-tables option],
 107     [libbacktrace_cv_c_unwind_tables],
 108     [CFLAGS_hold="$CFLAGS"
 109      CFLAGS="$CFLAGS -funwind-tables"
 110      AC_COMPILE_IFELSE(
 111        [AC_LANG_PROGRAM([static int f() { return 0; }], [return f();])],
 112        [libbacktrace_cv_c_unwind_tables=yes],
 113        [libbacktrace_cv_c_unwind_tables=no])
 114      CFLAGS="$CFLAGS_hold"])
 115   if test "$libbacktrace_cv_c_unwind_tables" = "yes"; then
 116     EXTRA_FLAGS=-funwind-tables
 117   fi
 118   AC_CACHE_CHECK([for -frandom-seed=string option],
 119     [libbacktrace_cv_c_random_seed_string],
 120     [CFLAGS_hold="$CFLAGS"
 121      CFLAGS="$CFLAGS -frandom-seed=conftest.lo"
 122      AC_COMPILE_IFELSE(
 123        [AC_LANG_PROGRAM([], [return 0;])],
 124        [libbacktrace_cv_c_random_seed_string=yes],
 125        [libbacktrace_cv_c_random_seed_string=no])
 126      CFLAGS="$CFLAGS_hold"])
 127   if test "$libbacktrace_cv_c_random_seed_string" = "yes"; then
 128     EXTRA_FLAGS="$EXTRA_FLAGS -frandom-seed=\$@"
 129   fi
 130 fi
 131 AC_SUBST(EXTRA_FLAGS)
 132
 133 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 134                           -Wmissing-prototypes -Wold-style-definition \
 135                           -Wmissing-format-attribute -Wcast-qual],
 136                           [WARN_FLAGS])
 137
 138 if test -n "${with_target_subdir}"; then
 139   WARN_FLAGS="$WARN_FLAGS -Werror"
 140 fi
 141
 142 AC_SUBST(WARN_FLAGS)
 143
 144 if test -n "${with_target_subdir}"; then
 145   GCC_CHECK_UNWIND_GETIPINFO
 146 else
 147   ac_save_CFFLAGS="$CFLAGS"
 148   CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
 149   AC_MSG_CHECKING([for _Unwind_GetIPInfo])
 150   AC_LINK_IFELSE(
 151     [AC_LANG_PROGRAM(
 152        [#include "unwind.h"
 153         struct _Unwind_Context *context;
 154         int ip_before_insn = 0;],
 155         [return _Unwind_GetIPInfo (context, &ip_before_insn);])],
 156         [have_unwind_getipinfo=yes], [have_unwind_getipinfo=no])
 157   CFLAGS="$ac_save_CFLAGS"
 158   AC_MSG_RESULT([$have_unwind_getipinfo])
 159   if test "$have_unwind_getipinfo" = "yes"; then
 160     AC_DEFINE(HAVE_GETIPINFO, 1, [Define if _Unwind_GetIPInfo is available.])
 161   fi
 162 fi
 163
 164 # When building as a target library, shared libraries may want to link
 165 # this in.  We don't want to provide another shared library to
 166 # complicate dependencies.  Instead, we just compile with -fPIC.
 167 PIC_FLAG=
 168 if test -n "${with_target_subdir}"; then
 169   PIC_FLAG=-fPIC
 170 fi
 171 # Similarly, use -fPIC with --enable-host-shared:
 172 AC_ARG_ENABLE(host-shared,
 173 [AS_HELP_STRING([--enable-host-shared],
 174                 [build host code as shared libraries])],
 175 [PIC_FLAG=-fPIC], [])
 176 AC_SUBST(PIC_FLAG)
 177
 178 # Test for __sync support.
 179 AC_CACHE_CHECK([__sync extensions],
 180 [libbacktrace_cv_sys_sync],
 181 [if test -n "${with_target_subdir}"; then
 182    libbacktrace_cv_sys_sync=yes
 183  else
 184    AC_LINK_IFELSE(
 185      [AC_LANG_PROGRAM([int i;],
 186                       [__sync_bool_compare_and_swap (&i, i, i);
 187                        __sync_lock_test_and_set (&i, 1);
 188                        __sync_lock_release (&i);])],
 189      [libbacktrace_cv_sys_sync=yes],
 190      [libbacktrace_cv_sys_sync=no])
 191  fi])
 192 BACKTRACE_SUPPORTS_THREADS=0
 193 if test "$libbacktrace_cv_sys_sync" = "yes"; then
 194   BACKTRACE_SUPPORTS_THREADS=1
 195   AC_DEFINE([HAVE_SYNC_FUNCTIONS], 1,
 196             [Define to 1 if you have the __sync functions])
 197 fi
 198 AC_SUBST(BACKTRACE_SUPPORTS_THREADS)
 199
 200 # Test for __atomic support.
 201 AC_CACHE_CHECK([__atomic extensions],
 202 [libbacktrace_cv_sys_atomic],
 203 [if test -n "${with_target_subdir}"; then
 204    libbacktrace_cv_sys_atomic=yes
 205  else
 206    AC_LINK_IFELSE(
 207      [AC_LANG_PROGRAM([int i;],
 208                       [__atomic_load_n (&i, __ATOMIC_ACQUIRE);
 209                        __atomic_store_n (&i, 1, __ATOMIC_RELEASE);])],
 210      [libbacktrace_cv_sys_atomic=yes],
 211      [libbacktrace_cv_sys_atomic=no])
 212  fi])
 213 if test "$libbacktrace_cv_sys_atomic" = "yes"; then
 214   AC_DEFINE([HAVE_ATOMIC_FUNCTIONS], 1,
 215             [Define to 1 if you have the __atomic functions])
 216 fi
 217
 218 # The library needs to be able to read the executable itself.  Compile
 219 # a file to determine the executable format.  The awk script
 220 # filetype.awk prints out the file type.
 221 AC_CACHE_CHECK([output filetype],
 222 [libbacktrace_cv_sys_filetype],
 223 [filetype=
 224 AC_COMPILE_IFELSE(
 225   [AC_LANG_PROGRAM([int i;], [int j;])],
 226   [filetype=`${AWK} -f $srcdir/filetype.awk conftest.$ac_objext`],
 227   [AC_MSG_FAILURE([compiler failed])])
 228 libbacktrace_cv_sys_filetype=$filetype])
 229
 230 # Match the file type to decide what files to compile.
 231 FORMAT_FILE=
 232 case "$libbacktrace_cv_sys_filetype" in
 233 elf*) FORMAT_FILE="elf.lo" ;;
 234 *) AC_MSG_WARN([could not determine output file type])
 235    FORMAT_FILE="unknown.lo"
 236    backtrace_supported=no
 237    ;;
 238 esac
 239 AC_SUBST(FORMAT_FILE)
 240
 241 # ELF defines.
 242 elfsize=
 243 case "$libbacktrace_cv_sys_filetype" in
 244 elf32) elfsize=32 ;;
 245 elf64) elfsize=64 ;;
 246 esac
 247 AC_DEFINE_UNQUOTED([BACKTRACE_ELF_SIZE], [$elfsize], [ELF size: 32 or 64])
 248
 249 BACKTRACE_SUPPORTED=0
 250 if test "$backtrace_supported" = "yes"; then
 251   BACKTRACE_SUPPORTED=1
 252 fi
 253 AC_SUBST(BACKTRACE_SUPPORTED)
 254
 255 GCC_HEADER_STDINT(gstdint.h)
 256
 257 AC_CHECK_HEADERS(sys/mman.h)
 258 if test "$ac_cv_header_sys_mman_h" = "no"; then
 259   have_mmap=no
 260 else
 261   if test -n "${with_target_subdir}"; then
 262     # When built as a GCC target library, we can't do a link test.  We
 263     # simply assume that if we have mman.h, we have mmap.
 264     have_mmap=yes
 265   else
 266     AC_CHECK_FUNC(mmap, [have_mmap=yes], [have_mmap=no])
 267   fi
 268 fi
 269 if test "$have_mmap" = "no"; then
 270   VIEW_FILE=read.lo
 271   ALLOC_FILE=alloc.lo
 272 else
 273   VIEW_FILE=mmapio.lo
 274   AC_PREPROC_IFELSE([
 275 #include <sys/mman.h>
 276 #if !defined(MAP_ANONYMOUS) && !defined(MAP_ANON)
 277   #error no MAP_ANONYMOUS
 278 #endif
 279 ], [ALLOC_FILE=mmap.lo], [ALLOC_FILE=alloc.lo])
 280 fi
 281 AC_SUBST(VIEW_FILE)
 282 AC_SUBST(ALLOC_FILE)
 283
 284 BACKTRACE_USES_MALLOC=0
 285 if test "$ALLOC_FILE" = "alloc.lo"; then
 286   BACKTRACE_USES_MALLOC=1
 287 fi
 288 AC_SUBST(BACKTRACE_USES_MALLOC)
 289
 290 # Check for dl_iterate_phdr.
 291 AC_CHECK_HEADERS(link.h)
 292 if test "$ac_cv_header_link_h" = "no"; then
 293   have_dl_iterate_phdr=no
 294 else
 295   if test -n "${with_target_subdir}"; then
 296     # When built as a GCC target library, we can't do a link test.
 297     AC_EGREP_HEADER([dl_iterate_phdr], [link.h], [have_dl_iterate_phdr=yes],
 298                     [have_dl_iterate_phdr=no])
 299     case "${host}" in
 300     *-*-solaris2.10*)
 301         # Avoid dl_iterate_phdr on Solaris 10, where it is in the
 302         # header file but is only in -ldl.
 303         have_dl_iterate_phdr=no ;;
 304     esac
 305   else
 306     AC_CHECK_FUNC([dl_iterate_phdr], [have_dl_iterate_phdr=yes],
 307                   [have_dl_iterate_phdr=no])
 308   fi
 309 fi
 310 if test "$have_dl_iterate_phdr" = "yes"; then
 311   AC_DEFINE(HAVE_DL_ITERATE_PHDR, 1, [Define if dl_iterate_phdr is available.])
 312 fi
 313
 314 # Check for the fcntl function.
 315 if test -n "${with_target_subdir}"; then
 316    case "${host}" in
 317    *-*-mingw*) have_fcntl=no ;;
 318    *) have_fcntl=yes ;;
 319    esac
 320 else
 321   AC_CHECK_FUNC(fcntl, [have_fcntl=yes], [have_fcntl=no])
 322 fi
 323 if test "$have_fcntl" = "yes"; then
 324   AC_DEFINE([HAVE_FCNTL], 1,
 325             [Define to 1 if you have the fcntl function])
 326 fi
 327
 328 AC_CHECK_DECLS(strnlen)
 329
 330 # Check for getexecname function.
 331 if test -n "${with_target_subdir}"; then
 332    case "${host}" in
 333    *-*-solaris2*) have_getexecname=yes ;;
 334    *) have_getexecname=no ;;
 335    esac
 336 else
 337   AC_CHECK_FUNC(getexecname, [have_getexecname=yes], [have_getexecname=no])
 338 fi
 339 if test "$have_getexecname" = "yes"; then
 340   AC_DEFINE(HAVE_GETEXECNAME, 1, [Define if getexecname is available.])
 341 fi
 342
 343 AC_CACHE_CHECK([whether tests can run],
 344   [libbacktrace_cv_sys_native],
 345   [AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 346      [libbacktrace_cv_sys_native=yes],
 347      [libbacktrace_cv_sys_native=no],
 348      [libbacktrace_cv_sys_native=no])])
 349 AM_CONDITIONAL(NATIVE, test "$libbacktrace_cv_sys_native" = "yes")
 350
 351 if test "${multilib}" = "yes"; then
 352   multilib_arg="--enable-multilib"
 353 else
 354   multilib_arg=
 355 fi
 356
 357 AC_CONFIG_FILES(Makefile backtrace-supported.h)
 358
 359 # We need multilib support, but only if configuring for the target.
 360 AC_CONFIG_COMMANDS([default],
 361 [if test -n "$CONFIG_FILES"; then
 362    if test -n "${with_target_subdir}"; then
 363      # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 364      # that multilib installs will end up installed in the correct place.
 365      # The testsuite needs it for multilib-aware ABI baseline files.
 366      # To work around this not being passed down from config-ml.in ->
 367      # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 368      # append it here.  Only modify Makefiles that have just been created.
 369      #
 370      # Also, get rid of this simulated-VPATH thing that automake does.
 371      cat > vpsed << \_EOF
 372   s!`test -f '$<' || echo '$(srcdir)/'`!!
 373 _EOF
 374      for i in $SUBDIRS; do
 375       case $CONFIG_FILES in
 376        *${i}/Makefile*)
 377          #echo "Adding MULTISUBDIR to $i/Makefile"
 378          sed -f vpsed $i/Makefile > tmp
 379          grep '^MULTISUBDIR =' Makefile >> tmp
 380          mv tmp $i/Makefile
 381          ;;
 382       esac
 383      done
 384      rm vpsed
 385    fi
 386  fi
 387 ],
 388 [
 389 # Variables needed in config.status (file generation) which aren't already
 390 # passed by autoconf.
 391 SUBDIRS="$SUBDIRS"
 392 ])
 393
 394 AC_OUTPUT