lib/libm/i386/e_exp.S

   1 /*
   2  * Copyright (c) 1993,94 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: head/lib/msun/i387/e_exp.S 217108 2011-01-07 16:13:12Z kib $
  31  */
  32
  33 /*
  34  * Written by:
  35  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  36  */
  37
  38 #include <machine/asm.h>
  39
  40 /* e^x = 2^(x * log2(e)) */
  41 ENTRY(exp)
  42         /*
  43          * If x is +-Inf, then the subtraction would give Inf-Inf = NaN.
  44          * Avoid this.  Also avoid it if x is NaN for convenience.
  45          */
  46         movl    8(%esp),%eax
  47         andl    $0x7fffffff,%eax
  48         cmpl    $0x7ff00000,%eax
  49         jae     x_Inf_or_NaN
  50
  51         fldl    4(%esp)
  52
  53         /*
  54          * Extended precision is needed to reduce the maximum error from
  55          * hundreds of ulps to less than 1 ulp.  Switch to it if necessary.
  56          * We may as well set the rounding mode to to-nearest and mask traps
  57          * if we switch.
  58          */
  59         fstcw   4(%esp)
  60         movl    4(%esp),%eax
  61         andl    $0x0300,%eax
  62         cmpl    $0x0300,%eax            /* RC == 0 && PC == 3? */
  63         je      1f                      /* jump if mode is good */
  64         movl    $0x137f,8(%esp)
  65         fldcw   8(%esp)
  66 1:
  67         fldl2e
  68         fmulp                           /* x * log2(e) */
  69         fst     %st(1)
  70         frndint                         /* int(x * log2(e)) */
  71         fst     %st(2)
  72         fsubrp                          /* fract(x * log2(e)) */
  73         f2xm1                           /* 2^(fract(x * log2(e))) - 1 */
  74         fld1
  75         faddp                           /* 2^(fract(x * log2(e))) */
  76         fscale                          /* e^x */
  77         fstp    %st(1)
  78         je      1f
  79         fldcw   4(%esp)
  80 1:
  81         ret
  82
  83 x_Inf_or_NaN:
  84         /*
  85          * Return 0 if x is -Inf.  Otherwise just return x; when x is Inf
  86          * this gives Inf, and when x is a NaN this gives the same result
  87          * as (x + x) (x quieted).
  88          */
  89         cmpl    $0xfff00000,8(%esp)
  90         jne     x_not_minus_Inf
  91         cmpl    $0,4(%esp)
  92         jne     x_not_minus_Inf
  93         fldz
  94         ret
  95
  96 x_not_minus_Inf:
  97         fldl    4(%esp)
  98         ret
  99 END(exp)
 100
 101         .section .note.GNU-stack,"",%progbits