contrib/binutils/opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(z8k-dis.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 # We currently only use the version number for the name of any shared
  11 # library.  For user convenience, we always use the same version
  12 # number that BFD is using.
  13 changequote(,)dnl
  14 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  15 changequote([,])dnl
  16
  17 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  18
  19 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  20 dnl to call AC_CHECK_PROG.
  21 AC_CHECK_TOOL(AR, ar)
  22 AC_CHECK_TOOL(RANLIB, ranlib, :)
  23
  24 dnl Default to a non shared library.  This may be overridden by the
  25 dnl configure option --enable-shared.
  26 AM_DISABLE_SHARED
  27
  28 AM_PROG_LIBTOOL
  29
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  44 esac])dnl
  45
  46 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  47 AC_ARG_ENABLE(build-warnings,
  48 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  49 [case "${enableval}" in
  50   yes)  ;;
  51   no)   build_warnings="-w";;
  52   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  53         build_warnings="${build_warnings} ${t}";;
  54   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  55         build_warnings="${t} ${build_warnings}";;
  56   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  57 esac
  58 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  59   echo "Setting warning flags = $build_warnings" 6>&1
  60 fi])dnl
  61 WARN_CFLAGS=""
  62 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  63     WARN_CFLAGS="${build_warnings}"
  64 fi
  65 AC_SUBST(WARN_CFLAGS)
  66
  67 AM_CONFIG_HEADER(config.h:config.in)
  68
  69 if test -z "$target" ; then
  70     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  71 fi
  72
  73 AM_MAINTAINER_MODE
  74 AC_EXEEXT
  75
  76 # host-specific stuff:
  77
  78 AC_PROG_CC
  79
  80 ALL_LINGUAS="fr sv tr es da de"
  81 CY_GNU_GETTEXT
  82
  83 . ${srcdir}/../bfd/configure.host
  84
  85 BFD_CC_FOR_BUILD
  86
  87 AC_SUBST(HDEFINES)
  88 AC_PROG_INSTALL
  89
  90 AC_CHECK_HEADERS(string.h strings.h stdlib.h)
  91
  92 cgen_maint=no
  93 cgendir='$(srcdir)/../cgen'
  94
  95 AC_ARG_ENABLE(cgen-maint,
  96 [  --enable-cgen-maint[=dir]    build cgen generated files],
  97 [case "${enableval}" in
  98   yes)  cgen_maint=yes ;;
  99   no)   cgen_maint=no ;;
 100   *)
 101         # argument is cgen install directory (not implemented yet).
 102         # Having a `share' directory might be more appropriate for the .scm,
 103         # .cpu, etc. files.
 104         cgen_maint=yes
 105         cgendir=${cgen_maint}/lib/cgen
 106         ;;
 107 esac])dnl
 108 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 109 AC_SUBST(cgendir)
 110
 111 using_cgen=no
 112
 113 # Horrible hacks to build DLLs on Windows.
 114 WIN32LDFLAGS=
 115 WIN32LIBADD=
 116 case "${host}" in
 117 *-*-cygwin*)
 118   if test "$enable_shared" = "yes"; then
 119     WIN32LDFLAGS="-no-undefined"
 120     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 121   fi
 122   ;;
 123 esac
 124 AC_SUBST(WIN32LDFLAGS)
 125 AC_SUBST(WIN32LIBADD)
 126
 127 # target-specific stuff:
 128
 129 # Canonicalize the secondary target names.
 130 if test -n "$enable_targets" ; then
 131     for targ in `echo $enable_targets | sed 's/,/ /g'`
 132     do
 133         result=`$ac_config_sub $targ 2>/dev/null`
 134         if test -n "$result" ; then
 135             canon_targets="$canon_targets $result"
 136         else
 137             # Allow targets that config.sub doesn't recognize, like "all".
 138             canon_targets="$canon_targets $targ"
 139         fi
 140     done
 141 fi
 142
 143 all_targets=false
 144 selarchs=
 145 for targ in $target $canon_targets
 146 do
 147     if test "x$targ" = "xall" ; then
 148         all_targets=true
 149     else
 150         . $srcdir/../bfd/config.bfd
 151         selarchs="$selarchs $targ_archs"
 152     fi
 153 done
 154
 155 # Utility var, documents generic cgen support files.
 156
 157 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo"
 158
 159 # We don't do any links based on the target system, just makefile config.
 160
 161 if test x${all_targets} = xfalse ; then
 162
 163     # Target architecture .o files.
 164     ta=
 165
 166     for arch in $selarchs
 167     do
 168         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 169         archdefs="$archdefs -DARCH_$ad"
 170         case "$arch" in
 171         bfd_a29k_arch)          ta="$ta a29k-dis.lo" ;;
 172         bfd_alliant_arch)       ;;
 173         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 174         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 175         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 176         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 177         bfd_convex_arch)        ;;
 178         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo" ;;
 179         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 180         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 181         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 182         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 183         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 184         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 185         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 186         bfd_i386_arch)          ta="$ta i386-dis.lo" ;;
 187         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 188         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 189         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 190         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 191         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 192         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 193         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 194         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 195         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 196         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 197         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 198         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 199         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 200         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 201         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 202         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 203         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 204         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 205         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 206         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 207         bfd_pyramid_arch)       ;;
 208         bfd_romp_arch)          ;;
 209         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 210         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 211         bfd_sh_arch)
 212           # We can't decide what we want just from the CPU family.
 213           # We want SH5 support unless a specific version of sh is
 214           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 215           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 216           for t in $target $canon_targets; do
 217             case $t in
 218               all |  sh64-* | sh-*-*elf* | shl-*-*elf* | sh-*-linux* | shl-*-linux*)
 219                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 220                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 221                                 break;;
 222             esac;
 223           done
 224                                 ta="$ta sh-dis.lo" ;;
 225         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 226         bfd_tahoe_arch)         ;;
 227         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 228         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 229         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 230         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 231         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 232         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 233         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 234         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 235         bfd_we32k_arch)         ;;
 236         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 237         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 238
 239         "")                     ;;
 240         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 241         esac
 242     done
 243
 244     if test $using_cgen = yes ; then
 245         ta="$ta $cgen_files"
 246     fi
 247
 248     # Weed out duplicate .o files.
 249     f=""
 250     for i in $ta ; do
 251         case " $f " in
 252         *" $i "*) ;;
 253         *) f="$f $i" ;;
 254         esac
 255     done
 256     ta="$f"
 257
 258     # And duplicate -D flags.
 259     f=""
 260     for i in $archdefs ; do
 261         case " $f " in
 262         *" $i "*) ;;
 263         *) f="$f $i" ;;
 264         esac
 265     done
 266     archdefs="$f"
 267
 268     BFD_MACHINES="$ta"
 269
 270 else    # all_targets is true
 271     archdefs=-DARCH_all
 272     BFD_MACHINES='$(ALL_MACHINES)'
 273 fi
 274
 275 AC_SUBST(archdefs)
 276 AC_SUBST(BFD_MACHINES)
 277
 278 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 279 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])