lib/libc/i386/string/swab.S

   1 /*
   2  * Copyright (c) 1993,94 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/swab.S,v 1.5 1999/08/27 23:59:35 peter Exp $
  31  */
  32
  33 #if defined(LIBC_RCS) && !defined(lint)
  34         .text
  35         .asciz "$FreeBSD: src/lib/libc/i386/string/swab.S,v 1.5 1999/08/27 23:59:35 peter Exp $"
  36 #endif
  37
  38 #include "DEFS.h"
  39
  40 /*
  41  * void
  42  * swab (const void *src, void *dst, size_t len)
  43  *      copy len bytes from src to dst, swapping adjacent bytes
  44  *
  45  * On the i486, this code is negligibly faster than the code generated
  46  * by gcc at about half the size.  If my i386 databook is correct, it
  47  * should be considerably faster than the gcc code on a i386.
  48  *
  49  * Written by:
  50  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  51  */
  52
  53 ENTRY(swab)
  54         pushl   %esi
  55         pushl   %edi
  56         movl    12(%esp),%esi
  57         movl    16(%esp),%edi
  58         movl    20(%esp),%ecx
  59
  60         cld                             # set direction forward
  61
  62         shrl    $1,%ecx
  63         testl   $7,%ecx                 # copy first group of 1 to 7 words
  64         jz      L2                      # while swaping alternate bytes.
  65         .align  2,0x90
  66 L1:     lodsw
  67         rorw    $8,%ax
  68         stosw
  69         decl    %ecx
  70         testl   $7,%ecx
  71         jnz     L1
  72
  73 L2:     shrl    $3,%ecx                 # copy remainder 8 words at a time
  74         jz      L4                      # while swapping alternate bytes.
  75         .align  2,0x90
  76 L3:     lodsw
  77         rorw    $8,%ax
  78         stosw
  79         lodsw
  80         rorw    $8,%ax
  81         stosw
  82         lodsw
  83         rorw    $8,%ax
  84         stosw
  85         lodsw
  86         rorw    $8,%ax
  87         stosw
  88         lodsw
  89         rorw    $8,%ax
  90         stosw
  91         lodsw
  92         rorw    $8,%ax
  93         stosw
  94         lodsw
  95         rorw    $8,%ax
  96         stosw
  97         lodsw
  98         rorw    $8,%ax
  99         stosw
 100         decl    %ecx
 101         jnz     L3
 102
 103 L4:     popl    %edi
 104         popl    %esi
 105         ret