contrib/perl5/lib/lib.pm

   1 package lib;
   2
   3 use vars qw(@ORIG_INC);
   4 use Config;
   5
   6 my $archname = $Config{'archname'};
   7
   8 @ORIG_INC = @INC;       # take a handy copy of 'original' value
   9
  10
  11 sub import {
  12     shift;
  13     foreach (reverse @_) {
  14         ## Ignore this if not defined.
  15         next unless defined($_);
  16         if ($_ eq '') {
  17             require Carp;
  18             Carp::carp("Empty compile time value given to use lib");
  19                                                         # at foo.pl line ...
  20         }
  21         if (-e && ! -d _) {
  22             require Carp;
  23             Carp::carp("Parameter to use lib must be directory, not file");
  24         }
  25         unshift(@INC, $_);
  26         # Put a corresponding archlib directory infront of $_ if it
  27         # looks like $_ has an archlib directory below it.
  28         if (-d "$_/$archname") {
  29             unshift(@INC, "$_/$archname")    if -d "$_/$archname/auto";
  30             unshift(@INC, "$_/$archname/$]") if -d "$_/$archname/$]/auto";
  31         }
  32     }
  33 }
  34
  35
  36 sub unimport {
  37     shift;
  38     my $mode = shift if $_[0] =~ m/^:[A-Z]+/;
  39
  40     my %names;
  41     foreach(@_) {
  42         ++$names{$_};
  43         ++$names{"$_/$archname"} if -d "$_/$archname/auto";
  44     }
  45
  46     if ($mode and $mode eq ':ALL') {
  47         # Remove ALL instances of each named directory.
  48         @INC = grep { !exists $names{$_} } @INC;
  49     } else {
  50         # Remove INITIAL instance(s) of each named directory.
  51         @INC = grep { --$names{$_} < 0   } @INC;
  52     }
  53 }
  54
  55 1;
  56 __END__
  57
  58 =head1 NAME
  59
  60 lib - manipulate @INC at compile time
  61
  62 =head1 SYNOPSIS
  63
  64     use lib LIST;
  65
  66     no lib LIST;
  67
  68 =head1 DESCRIPTION
  69
  70 This is a small simple module which simplifies the manipulation of @INC
  71 at compile time.
  72
  73 It is typically used to add extra directories to perl's search path so
  74 that later C<use> or C<require> statements will find modules which are
  75 not located on perl's default search path.
  76
  77 =head2 ADDING DIRECTORIES TO @INC
  78
  79 The parameters to C<use lib> are added to the start of the perl search
  80 path. Saying
  81
  82     use lib LIST;
  83
  84 is I<almost> the same as saying
  85
  86     BEGIN { unshift(@INC, LIST) }
  87
  88 For each directory in LIST (called $dir here) the lib module also
  89 checks to see if a directory called $dir/$archname/auto exists.
  90 If so the $dir/$archname directory is assumed to be a corresponding
  91 architecture specific directory and is added to @INC in front of $dir.
  92
  93 If LIST includes both $dir and $dir/$archname then $dir/$archname will
  94 be added to @INC twice (if $dir/$archname/auto exists).
  95
  96 =head2 DELETING DIRECTORIES FROM @INC
  97
  98 You should normally only add directories to @INC.  If you need to
  99 delete directories from @INC take care to only delete those which you
 100 added yourself or which you are certain are not needed by other modules
 101 in your script.  Other modules may have added directories which they
 102 need for correct operation.
 103
 104 By default the C<no lib> statement deletes the I<first> instance of
 105 each named directory from @INC.  To delete multiple instances of the
 106 same name from @INC you can specify the name multiple times.
 107
 108 To delete I<all> instances of I<all> the specified names from @INC you can
 109 specify ':ALL' as the first parameter of C<no lib>. For example:
 110
 111     no lib qw(:ALL .);
 112
 113 For each directory in LIST (called $dir here) the lib module also
 114 checks to see if a directory called $dir/$archname/auto exists.
 115 If so the $dir/$archname directory is assumed to be a corresponding
 116 architecture specific directory and is also deleted from @INC.
 117
 118 If LIST includes both $dir and $dir/$archname then $dir/$archname will
 119 be deleted from @INC twice (if $dir/$archname/auto exists).
 120
 121 =head2 RESTORING ORIGINAL @INC
 122
 123 When the lib module is first loaded it records the current value of @INC
 124 in an array C<@lib::ORIG_INC>. To restore @INC to that value you
 125 can say
 126
 127     @INC = @lib::ORIG_INC;
 128
 129
 130 =head1 SEE ALSO
 131
 132 FindBin - optional module which deals with paths relative to the source file.
 133
 134 =head1 AUTHOR
 135
 136 Tim Bunce, 2nd June 1995.
 137
 138 =cut
 139