sys/i386/i386/locore.s

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  *      from: @(#)locore.s      7.3 (Berkeley) 5/13/91
  37  * $FreeBSD: src/sys/i386/i386/locore.s,v 1.132.2.10 2003/02/03 20:54:49 jhb Exp $
  38  *
  39  *              originally from: locore.s, by William F. Jolitz
  40  *
  41  *              Substantially rewritten by David Greenman, Rod Grimes,
  42  *                      Bruce Evans, Wolfgang Solfrank, Poul-Henning Kamp
  43  *                      and many others.
  44  */
  45
  46 #include "opt_bootp.h"
  47 #include "opt_nfsroot.h"
  48
  49 #include <sys/syscall.h>
  50 #include <sys/reboot.h>
  51
  52 #include <machine/asmacros.h>
  53 #include <machine/cputypes.h>
  54 #include <machine/psl.h>
  55 #include <machine/pmap.h>
  56 #include <machine/specialreg.h>
  57
  58 #include "assym.s"
  59
  60 /*
  61  *      XXX
  62  *
  63  * Note: This version greatly munged to avoid various assembler errors
  64  * that may be fixed in newer versions of gas. Perhaps newer versions
  65  * will have more pleasant appearance.
  66  */
  67
  68 /*
  69  * PTmap is recursive pagemap at top of virtual address space.
  70  * Within PTmap, the page directory can be found (third indirection).
  71  */
  72         .globl  _PTmap,_PTD,_PTDpde
  73         .set    _PTmap,(PTDPTDI << PDRSHIFT)
  74         .set    _PTD,_PTmap + (PTDPTDI * PAGE_SIZE)
  75         .set    _PTDpde,_PTD + (PTDPTDI * PDESIZE)
  76
  77 /*
  78  * APTmap, APTD is the alternate recursive pagemap.
  79  * It's used when modifying another process's page tables.
  80  */
  81         .globl  _APTmap,_APTD,_APTDpde
  82         .set    _APTmap,APTDPTDI << PDRSHIFT
  83         .set    _APTD,_APTmap + (APTDPTDI * PAGE_SIZE)
  84         .set    _APTDpde,_PTD + (APTDPTDI * PDESIZE)
  85
  86 /*
  87  * Compiled KERNBASE location
  88  */
  89         .globl  _kernbase
  90         .set    _kernbase,KERNBASE
  91
  92 /*
  93  * Globals
  94  */
  95         .data
  96         ALIGN_DATA              /* just to be sure */
  97
  98         .globl  HIDENAME(tmpstk)
  99         .space  0x2000          /* space for tmpstk - temporary stack */
 100 HIDENAME(tmpstk):
 101
 102         .globl  _boothowto,_bootdev
 103
 104         .globl  _cpu,_cpu_vendor,_cpu_id,_bootinfo
 105         .globl  _cpu_high, _cpu_feature, _cpu_procinfo
 106
 107 _cpu:           .long   0                       /* are we 386, 386sx, or 486 */
 108 _cpu_id:        .long   0                       /* stepping ID */
 109 _cpu_high:      .long   0                       /* highest arg to CPUID */
 110 _cpu_feature:   .long   0                       /* features */
 111 _cpu_procinfo:  .long   0                       /* brand index / HTT info */
 112 _cpu_vendor:    .space  20                      /* CPU origin code */
 113 _bootinfo:      .space  BOOTINFO_SIZE           /* bootinfo that we can handle */
 114
 115 _KERNend:       .long   0                       /* phys addr end of kernel (just after bss) */
 116 physfree:       .long   0                       /* phys addr of next free page */
 117
 118 #ifdef SMP
 119                 .globl  _cpu0prvpage
 120 cpu0pp:         .long   0                       /* phys addr cpu0 private pg */
 121 _cpu0prvpage:   .long   0                       /* relocated version */
 122
 123                 .globl  _SMPpt
 124 SMPptpa:        .long   0                       /* phys addr SMP page table */
 125 _SMPpt:         .long   0                       /* relocated version */
 126 #endif /* SMP */
 127
 128         .globl  _IdlePTD
 129 _IdlePTD:       .long   0                       /* phys addr of kernel PTD */
 130
 131 #ifdef SMP
 132         .globl  _KPTphys
 133 #endif
 134 _KPTphys:       .long   0                       /* phys addr of kernel page tables */
 135
 136         .globl  _proc0paddr
 137 _proc0paddr:    .long   0                       /* address of proc 0 address space */
 138 p0upa:          .long   0                       /* phys addr of proc0's UPAGES */
 139
 140 vm86phystk:     .long   0                       /* PA of vm86/bios stack */
 141
 142         .globl  _vm86paddr, _vm86pa
 143 _vm86paddr:     .long   0                       /* address of vm86 region */
 144 _vm86pa:        .long   0                       /* phys addr of vm86 region */
 145
 146 #ifdef BDE_DEBUGGER
 147         .globl  _bdb_exists                     /* flag to indicate BDE debugger is present */
 148 _bdb_exists:    .long   0
 149 #endif
 150
 151 #ifdef PC98
 152         .globl  _pc98_system_parameter
 153 _pc98_system_parameter:
 154         .space  0x240
 155 #endif
 156
 157 /**********************************************************************
 158  *
 159  * Some handy macros
 160  *
 161  */
 162
 163 #define R(foo) ((foo)-KERNBASE)
 164
 165 #define ALLOCPAGES(foo) \
 166         movl    R(physfree), %esi ; \
 167         movl    $((foo)*PAGE_SIZE), %eax ; \
 168         addl    %esi, %eax ; \
 169         movl    %eax, R(physfree) ; \
 170         movl    %esi, %edi ; \
 171         movl    $((foo)*PAGE_SIZE),%ecx ; \
 172         xorl    %eax,%eax ; \
 173         cld ; \
 174         rep ; \
 175         stosb
 176
 177 /*
 178  * fillkpt
 179  *      eax = page frame address
 180  *      ebx = index into page table
 181  *      ecx = how many pages to map
 182  *      base = base address of page dir/table
 183  *      prot = protection bits
 184  */
 185 #define fillkpt(base, prot)               \
 186         shll    $2,%ebx                 ; \
 187         addl    base,%ebx               ; \
 188         orl     $PG_V,%eax              ; \
 189         orl     prot,%eax               ; \
 190 1:      movl    %eax,(%ebx)             ; \
 191         addl    $PAGE_SIZE,%eax         ; /* increment physical address */ \
 192         addl    $4,%ebx                 ; /* next pte */ \
 193         loop    1b
 194
 195 /*
 196  * fillkptphys(prot)
 197  *      eax = physical address
 198  *      ecx = how many pages to map
 199  *      prot = protection bits
 200  */
 201 #define fillkptphys(prot)                 \
 202         movl    %eax, %ebx              ; \
 203         shrl    $PAGE_SHIFT, %ebx       ; \
 204         fillkpt(R(_KPTphys), prot)
 205
 206         .text
 207 /**********************************************************************
 208  *
 209  * This is where the bootblocks start us, set the ball rolling...
 210  *
 211  */
 212 NON_GPROF_ENTRY(btext)
 213
 214 #ifdef PC98
 215         /* save SYSTEM PARAMETER for resume (NS/T or other) */
 216         movl    $0xa1400,%esi
 217         movl    $R(_pc98_system_parameter),%edi
 218         movl    $0x0240,%ecx
 219         cld
 220         rep
 221         movsb
 222 #else   /* IBM-PC */
 223 #ifdef BDE_DEBUGGER
 224 #ifdef BIOS_STEALS_3K
 225         cmpl    $0x0375c339,0x95504
 226 #else
 227         cmpl    $0x0375c339,0x96104     /* XXX - debugger signature */
 228 #endif
 229         jne     1f
 230         movb    $1,R(_bdb_exists)
 231 1:
 232 #endif
 233 /* Tell the bios to warmboot next time */
 234         movw    $0x1234,0x472
 235 #endif  /* PC98 */
 236
 237 /* Set up a real frame in case the double return in newboot is executed. */
 238         pushl   %ebp
 239         movl    %esp, %ebp
 240
 241 /* Don't trust what the BIOS gives for eflags. */
 242         pushl   $PSL_KERNEL
 243         popfl
 244
 245 /*
 246  * Don't trust what the BIOS gives for %fs and %gs.  Trust the bootstrap
 247  * to set %cs, %ds, %es and %ss.
 248  */
 249         mov     %ds, %ax
 250         mov     %ax, %fs
 251         mov     %ax, %gs
 252
 253         call    recover_bootinfo
 254
 255 /* Get onto a stack that we can trust. */
 256 /*
 257  * XXX this step is delayed in case recover_bootinfo needs to return via
 258  * the old stack, but it need not be, since recover_bootinfo actually
 259  * returns via the old frame.
 260  */
 261         movl    $R(HIDENAME(tmpstk)),%esp
 262
 263 #ifdef PC98
 264         /* pc98_machine_type & M_EPSON_PC98 */
 265         testb   $0x02,R(_pc98_system_parameter)+220
 266         jz      3f
 267         /* epson_machine_id <= 0x0b */
 268         cmpb    $0x0b,R(_pc98_system_parameter)+224
 269         ja      3f
 270
 271         /* count up memory */
 272         movl    $0x100000,%eax          /* next, talley remaining memory */
 273         movl    $0xFFF-0x100,%ecx
 274 1:      movl    0(%eax),%ebx            /* save location to check */
 275         movl    $0xa55a5aa5,0(%eax)     /* write test pattern */
 276         cmpl    $0xa55a5aa5,0(%eax)     /* does not check yet for rollover */
 277         jne     2f
 278         movl    %ebx,0(%eax)            /* restore memory */
 279         addl    $PAGE_SIZE,%eax
 280         loop    1b
 281 2:      subl    $0x100000,%eax
 282         shrl    $17,%eax
 283         movb    %al,R(_pc98_system_parameter)+1
 284 3:
 285
 286         movw    R(_pc98_system_parameter+0x86),%ax
 287         movw    %ax,R(_cpu_id)
 288 #endif
 289
 290         call    identify_cpu
 291
 292 /* clear bss */
 293 /*
 294  * XXX this should be done a little earlier.
 295  *
 296  * XXX we don't check that there is memory for our bss and page tables
 297  * before using it.
 298  *
 299  * XXX the boot program somewhat bogusly clears the bss.  We still have
 300  * to do it in case we were unzipped by kzipboot.  Then the boot program
 301  * only clears kzipboot's bss.
 302  *
 303  * XXX the gdt and idt are still somewhere in the boot program.  We
 304  * depend on the convention that the boot program is below 1MB and we
 305  * are above 1MB to keep the gdt and idt  away from the bss and page
 306  * tables.  The idt is only used if BDE_DEBUGGER is enabled.
 307  */
 308         movl    $R(_end),%ecx
 309         movl    $R(_edata),%edi
 310         subl    %edi,%ecx
 311         xorl    %eax,%eax
 312         cld
 313         rep
 314         stosb
 315
 316         call    create_pagetables
 317
 318 /*
 319  * If the CPU has support for VME, turn it on.
 320  */
 321         testl   $CPUID_VME, R(_cpu_feature)
 322         jz      1f
 323         movl    %cr4, %eax
 324         orl     $CR4_VME, %eax
 325         movl    %eax, %cr4
 326 1:
 327
 328 #ifdef BDE_DEBUGGER
 329 /*
 330  * Adjust as much as possible for paging before enabling paging so that the
 331  * adjustments can be traced.
 332  */
 333         call    bdb_prepare_paging
 334 #endif
 335
 336 /* Now enable paging */
 337         movl    R(_IdlePTD), %eax
 338         movl    %eax,%cr3                       /* load ptd addr into mmu */
 339         movl    %cr0,%eax                       /* get control word */
 340         orl     $CR0_PE|CR0_PG,%eax             /* enable paging */
 341         movl    %eax,%cr0                       /* and let's page NOW! */
 342
 343 #ifdef BDE_DEBUGGER
 344 /*
 345  * Complete the adjustments for paging so that we can keep tracing through
 346  * initi386() after the low (physical) addresses for the gdt and idt become
 347  * invalid.
 348  */
 349         call    bdb_commit_paging
 350 #endif
 351
 352         pushl   $begin                          /* jump to high virtualized address */
 353         ret
 354
 355 /* now running relocated at KERNBASE where the system is linked to run */
 356 begin:
 357         /* set up bootstrap stack */
 358         movl    _proc0paddr,%esp        /* location of in-kernel pages */
 359         addl    $UPAGES*PAGE_SIZE,%esp  /* bootstrap stack end location */
 360         xorl    %eax,%eax                       /* mark end of frames */
 361         movl    %eax,%ebp
 362         movl    _proc0paddr,%eax
 363         movl    _IdlePTD, %esi
 364         movl    %esi,PCB_CR3(%eax)
 365
 366         testl   $CPUID_PGE, R(_cpu_feature)
 367         jz      1f
 368         movl    %cr4, %eax
 369         orl     $CR4_PGE, %eax
 370         movl    %eax, %cr4
 371 1:
 372
 373         movl    physfree, %esi
 374         pushl   %esi                            /* value of first for init386(first) */
 375         call    _init386                        /* wire 386 chip for unix operation */
 376         popl    %esi
 377
 378         call    _mi_startup                     /* autoconfiguration, mountroot etc */
 379
 380         hlt             /* never returns to here */
 381
 382 /*
 383  * Signal trampoline, copied to top of user stack
 384  */
 385 NON_GPROF_ENTRY(sigcode)
 386         call    *SIGF_HANDLER(%esp)             /* call signal handler */
 387         lea     SIGF_UC(%esp),%eax              /* get ucontext_t */
 388         pushl   %eax
 389         testl   $PSL_VM,UC_EFLAGS(%eax)
 390         jne     9f
 391         movl    UC_GS(%eax),%gs                 /* restore %gs */
 392 9:
 393         movl    $SYS_sigreturn,%eax
 394         pushl   %eax                            /* junk to fake return addr. */
 395         int     $0x80                           /* enter kernel with args */
 396 0:      jmp     0b
 397
 398         ALIGN_TEXT
 399 _osigcode:
 400         call    *SIGF_HANDLER(%esp)             /* call signal handler */
 401         lea     SIGF_SC(%esp),%eax              /* get sigcontext */
 402         pushl   %eax
 403         testl   $PSL_VM,SC_PS(%eax)
 404         jne     9f
 405         movl    SC_GS(%eax),%gs                 /* restore %gs */
 406 9:
 407         movl    $0x01d516,SC_TRAPNO(%eax)       /* magic: 0ldSiG */
 408         movl    $SYS_sigreturn,%eax
 409         pushl   %eax                            /* junk to fake return addr. */
 410         int     $0x80                           /* enter kernel with args */
 411 0:      jmp     0b
 412
 413         ALIGN_TEXT
 414 _esigcode:
 415
 416         .data
 417         .globl  _szsigcode, _szosigcode
 418 _szsigcode:
 419         .long   _esigcode-_sigcode
 420 _szosigcode:
 421         .long   _esigcode-_osigcode
 422         .text
 423
 424 /**********************************************************************
 425  *
 426  * Recover the bootinfo passed to us from the boot program
 427  *
 428  */
 429 recover_bootinfo:
 430         /*
 431          * This code is called in different ways depending on what loaded
 432          * and started the kernel.  This is used to detect how we get the
 433          * arguments from the other code and what we do with them.
 434          *
 435          * Old disk boot blocks:
 436          *      (*btext)(howto, bootdev, cyloffset, esym);
 437          *      [return address == 0, and can NOT be returned to]
 438          *      [cyloffset was not supported by the FreeBSD boot code
 439          *       and always passed in as 0]
 440          *      [esym is also known as total in the boot code, and
 441          *       was never properly supported by the FreeBSD boot code]
 442          *
 443          * Old diskless netboot code:
 444          *      (*btext)(0,0,0,0,&nfsdiskless,0,0,0);
 445          *      [return address != 0, and can NOT be returned to]
 446          *      If we are being booted by this code it will NOT work,
 447          *      so we are just going to halt if we find this case.
 448          *
 449          * New uniform boot code:
 450          *      (*btext)(howto, bootdev, 0, 0, 0, &bootinfo)
 451          *      [return address != 0, and can be returned to]
 452          *
 453          * There may seem to be a lot of wasted arguments in here, but
 454          * that is so the newer boot code can still load very old kernels
 455          * and old boot code can load new kernels.
 456          */
 457
 458         /*
 459          * The old style disk boot blocks fake a frame on the stack and
 460          * did an lret to get here.  The frame on the stack has a return
 461          * address of 0.
 462          */
 463         cmpl    $0,4(%ebp)
 464         je      olddiskboot
 465
 466         /*
 467          * We have some form of return address, so this is either the
 468          * old diskless netboot code, or the new uniform code.  That can
 469          * be detected by looking at the 5th argument, if it is 0
 470          * we are being booted by the new uniform boot code.
 471          */
 472         cmpl    $0,24(%ebp)
 473         je      newboot
 474
 475         /*
 476          * Seems we have been loaded by the old diskless boot code, we
 477          * don't stand a chance of running as the diskless structure
 478          * changed considerably between the two, so just halt.
 479          */
 480          hlt
 481
 482         /*
 483          * We have been loaded by the new uniform boot code.
 484          * Let's check the bootinfo version, and if we do not understand
 485          * it we return to the loader with a status of 1 to indicate this error
 486          */
 487 newboot:
 488         movl    28(%ebp),%ebx           /* &bootinfo.version */
 489         movl    BI_VERSION(%ebx),%eax
 490         cmpl    $1,%eax                 /* We only understand version 1 */
 491         je      1f
 492         movl    $1,%eax                 /* Return status */
 493         leave
 494         /*
 495          * XXX this returns to our caller's caller (as is required) since
 496          * we didn't set up a frame and our caller did.
 497          */
 498         ret
 499
 500 1:
 501         /*
 502          * If we have a kernelname copy it in
 503          */
 504         movl    BI_KERNELNAME(%ebx),%esi
 505         cmpl    $0,%esi
 506         je      2f                      /* No kernelname */
 507         movl    $MAXPATHLEN,%ecx        /* Brute force!!! */
 508         movl    $R(_kernelname),%edi
 509         cmpb    $'/',(%esi)             /* Make sure it starts with a slash */
 510         je      1f
 511         movb    $'/',(%edi)
 512         incl    %edi
 513         decl    %ecx
 514 1:
 515         cld
 516         rep
 517         movsb
 518
 519 2:
 520         /*
 521          * Determine the size of the boot loader's copy of the bootinfo
 522          * struct.  This is impossible to do properly because old versions
 523          * of the struct don't contain a size field and there are 2 old
 524          * versions with the same version number.
 525          */
 526         movl    $BI_ENDCOMMON,%ecx      /* prepare for sizeless version */
 527         testl   $RB_BOOTINFO,8(%ebp)    /* bi_size (and bootinfo) valid? */
 528         je      got_bi_size             /* no, sizeless version */
 529         movl    BI_SIZE(%ebx),%ecx
 530 got_bi_size:
 531
 532         /*
 533          * Copy the common part of the bootinfo struct
 534          */
 535         movl    %ebx,%esi
 536         movl    $R(_bootinfo),%edi
 537         cmpl    $BOOTINFO_SIZE,%ecx
 538         jbe     got_common_bi_size
 539         movl    $BOOTINFO_SIZE,%ecx
 540 got_common_bi_size:
 541         cld
 542         rep
 543         movsb
 544
 545 #ifdef NFS_ROOT
 546 #ifndef BOOTP_NFSV3
 547         /*
 548          * If we have a nfs_diskless structure copy it in
 549          */
 550         movl    BI_NFS_DISKLESS(%ebx),%esi
 551         cmpl    $0,%esi
 552         je      olddiskboot
 553         movl    $R(_nfs_diskless),%edi
 554         movl    $NFSDISKLESS_SIZE,%ecx
 555         cld
 556         rep
 557         movsb
 558         movl    $R(_nfs_diskless_valid),%edi
 559         movl    $1,(%edi)
 560 #endif
 561 #endif
 562
 563         /*
 564          * The old style disk boot.
 565          *      (*btext)(howto, bootdev, cyloffset, esym);
 566          * Note that the newer boot code just falls into here to pick
 567          * up howto and bootdev, cyloffset and esym are no longer used
 568          */
 569 olddiskboot:
 570         movl    8(%ebp),%eax
 571         movl    %eax,R(_boothowto)
 572         movl    12(%ebp),%eax
 573         movl    %eax,R(_bootdev)
 574
 575         ret
 576
 577
 578 /**********************************************************************
 579  *
 580  * Identify the CPU and initialize anything special about it
 581  *
 582  */
 583 identify_cpu:
 584
 585         /* Try to toggle alignment check flag; does not exist on 386. */
 586         pushfl
 587         popl    %eax
 588         movl    %eax,%ecx
 589         orl     $PSL_AC,%eax
 590         pushl   %eax
 591         popfl
 592         pushfl
 593         popl    %eax
 594         xorl    %ecx,%eax
 595         andl    $PSL_AC,%eax
 596         pushl   %ecx
 597         popfl
 598
 599         testl   %eax,%eax
 600         jnz     try486
 601
 602         /* NexGen CPU does not have aligment check flag. */
 603         pushfl
 604         movl    $0x5555, %eax
 605         xorl    %edx, %edx
 606         movl    $2, %ecx
 607         clc
 608         divl    %ecx
 609         jz      trynexgen
 610         popfl
 611         movl    $CPU_386,R(_cpu)
 612         jmp     3f
 613
 614 trynexgen:
 615         popfl
 616         movl    $CPU_NX586,R(_cpu)
 617         movl    $0x4778654e,R(_cpu_vendor)      # store vendor string
 618         movl    $0x72446e65,R(_cpu_vendor+4)
 619         movl    $0x6e657669,R(_cpu_vendor+8)
 620         movl    $0,R(_cpu_vendor+12)
 621         jmp     3f
 622
 623 try486: /* Try to toggle identification flag; does not exist on early 486s. */
 624         pushfl
 625         popl    %eax
 626         movl    %eax,%ecx
 627         xorl    $PSL_ID,%eax
 628         pushl   %eax
 629         popfl
 630         pushfl
 631         popl    %eax
 632         xorl    %ecx,%eax
 633         andl    $PSL_ID,%eax
 634         pushl   %ecx
 635         popfl
 636
 637         testl   %eax,%eax
 638         jnz     trycpuid
 639         movl    $CPU_486,R(_cpu)
 640
 641         /*
 642          * Check Cyrix CPU
 643          * Cyrix CPUs do not change the undefined flags following
 644          * execution of the divide instruction which divides 5 by 2.
 645          *
 646          * Note: CPUID is enabled on M2, so it passes another way.
 647          */
 648         pushfl
 649         movl    $0x5555, %eax
 650         xorl    %edx, %edx
 651         movl    $2, %ecx
 652         clc
 653         divl    %ecx
 654         jnc     trycyrix
 655         popfl
 656         jmp     3f              /* You may use Intel CPU. */
 657
 658 trycyrix:
 659         popfl
 660         /*
 661          * IBM Bluelighting CPU also doesn't change the undefined flags.
 662          * Because IBM doesn't disclose the information for Bluelighting
 663          * CPU, we couldn't distinguish it from Cyrix's (including IBM
 664          * brand of Cyrix CPUs).
 665          */
 666         movl    $0x69727943,R(_cpu_vendor)      # store vendor string
 667         movl    $0x736e4978,R(_cpu_vendor+4)
 668         movl    $0x64616574,R(_cpu_vendor+8)
 669         jmp     3f
 670
 671 trycpuid:       /* Use the `cpuid' instruction. */
 672         xorl    %eax,%eax
 673         cpuid                                   # cpuid 0
 674         movl    %eax,R(_cpu_high)               # highest capability
 675         movl    %ebx,R(_cpu_vendor)             # store vendor string
 676         movl    %edx,R(_cpu_vendor+4)
 677         movl    %ecx,R(_cpu_vendor+8)
 678         movb    $0,R(_cpu_vendor+12)
 679
 680         movl    $1,%eax
 681         cpuid                                   # cpuid 1
 682         movl    %eax,R(_cpu_id)                 # store cpu_id
 683         movl    %ebx,R(_cpu_procinfo)           # store cpu_procinfo
 684         movl    %edx,R(_cpu_feature)            # store cpu_feature
 685         rorl    $8,%eax                         # extract family type
 686         andl    $15,%eax
 687         cmpl    $5,%eax
 688         jae     1f
 689
 690         /* less than Pentium; must be 486 */
 691         movl    $CPU_486,R(_cpu)
 692         jmp     3f
 693 1:
 694         /* a Pentium? */
 695         cmpl    $5,%eax
 696         jne     2f
 697         movl    $CPU_586,R(_cpu)
 698         jmp     3f
 699 2:
 700         /* Greater than Pentium...call it a Pentium Pro */
 701         movl    $CPU_686,R(_cpu)
 702 3:
 703         ret
 704
 705
 706 /**********************************************************************
 707  *
 708  * Create the first page directory and its page tables.
 709  *
 710  */
 711
 712 create_pagetables:
 713
 714 /* Find end of kernel image (rounded up to a page boundary). */
 715         movl    $R(_end),%esi
 716
 717 /* Include symbols, if any. */
 718         movl    R(_bootinfo+BI_ESYMTAB),%edi
 719         testl   %edi,%edi
 720         je      over_symalloc
 721         movl    %edi,%esi
 722         movl    $KERNBASE,%edi
 723         addl    %edi,R(_bootinfo+BI_SYMTAB)
 724         addl    %edi,R(_bootinfo+BI_ESYMTAB)
 725 over_symalloc:
 726
 727 /* If we are told where the end of the kernel space is, believe it. */
 728         movl    R(_bootinfo+BI_KERNEND),%edi
 729         testl   %edi,%edi
 730         je      no_kernend
 731         movl    %edi,%esi
 732 no_kernend:
 733
 734         addl    $PAGE_MASK,%esi
 735         andl    $~PAGE_MASK,%esi
 736         movl    %esi,R(_KERNend)        /* save end of kernel */
 737         movl    %esi,R(physfree)        /* next free page is at end of kernel */
 738
 739 /* Allocate Kernel Page Tables */
 740         ALLOCPAGES(NKPT)
 741         movl    %esi,R(_KPTphys)
 742
 743 /* Allocate Page Table Directory */
 744         ALLOCPAGES(1)
 745         movl    %esi,R(_IdlePTD)
 746
 747 /* Allocate UPAGES */
 748         ALLOCPAGES(UPAGES)
 749         movl    %esi,R(p0upa)
 750         addl    $KERNBASE, %esi
 751         movl    %esi, R(_proc0paddr)
 752
 753         ALLOCPAGES(1)                   /* vm86/bios stack */
 754         movl    %esi,R(vm86phystk)
 755
 756         ALLOCPAGES(3)                   /* pgtable + ext + IOPAGES */
 757         movl    %esi,R(_vm86pa)
 758         addl    $KERNBASE, %esi
 759         movl    %esi, R(_vm86paddr)
 760
 761 #ifdef SMP
 762 /* Allocate cpu0's private data page */
 763         ALLOCPAGES(1)
 764         movl    %esi,R(cpu0pp)
 765         addl    $KERNBASE, %esi
 766         movl    %esi, R(_cpu0prvpage)   /* relocated to KVM space */
 767
 768 /* Allocate SMP page table page */
 769         ALLOCPAGES(1)
 770         movl    %esi,R(SMPptpa)
 771         addl    $KERNBASE, %esi
 772         movl    %esi, R(_SMPpt)         /* relocated to KVM space */
 773 #endif  /* SMP */
 774
 775 /* Map read-only from zero to the end of the kernel text section */
 776         xorl    %eax, %eax
 777 #ifdef BDE_DEBUGGER
 778 /* If the debugger is present, actually map everything read-write. */
 779         cmpl    $0,R(_bdb_exists)
 780         jne     map_read_write
 781 #endif
 782         xorl    %edx,%edx
 783
 784 #if !defined(SMP)
 785         testl   $CPUID_PGE, R(_cpu_feature)
 786         jz      2f
 787         orl     $PG_G,%edx
 788 #endif
 789
 790 2:      movl    $R(_etext),%ecx
 791         addl    $PAGE_MASK,%ecx
 792         shrl    $PAGE_SHIFT,%ecx
 793         fillkptphys(%edx)
 794
 795 /* Map read-write, data, bss and symbols */
 796         movl    $R(_etext),%eax
 797         addl    $PAGE_MASK, %eax
 798         andl    $~PAGE_MASK, %eax
 799 map_read_write:
 800         movl    $PG_RW,%edx
 801 #if !defined(SMP)
 802         testl   $CPUID_PGE, R(_cpu_feature)
 803         jz      1f
 804         orl     $PG_G,%edx
 805 #endif
 806
 807 1:      movl    R(_KERNend),%ecx
 808         subl    %eax,%ecx
 809         shrl    $PAGE_SHIFT,%ecx
 810         fillkptphys(%edx)
 811
 812 /* Map page directory. */
 813         movl    R(_IdlePTD), %eax
 814         movl    $1, %ecx
 815         fillkptphys($PG_RW)
 816
 817 /* Map proc0's UPAGES in the physical way ... */
 818         movl    R(p0upa), %eax
 819         movl    $UPAGES, %ecx
 820         fillkptphys($PG_RW)
 821
 822 /* Map ISA hole */
 823         movl    $ISA_HOLE_START, %eax
 824         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 825         fillkptphys($PG_RW)
 826
 827 /* Map space for the vm86 region */
 828         movl    R(vm86phystk), %eax
 829         movl    $4, %ecx
 830         fillkptphys($PG_RW)
 831
 832 /* Map page 0 into the vm86 page table */
 833         movl    $0, %eax
 834         movl    $0, %ebx
 835         movl    $1, %ecx
 836         fillkpt(R(_vm86pa), $PG_RW|PG_U)
 837
 838 /* ...likewise for the ISA hole */
 839         movl    $ISA_HOLE_START, %eax
 840         movl    $ISA_HOLE_START>>PAGE_SHIFT, %ebx
 841         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 842         fillkpt(R(_vm86pa), $PG_RW|PG_U)
 843
 844 #ifdef SMP
 845 /* Map cpu0's private page into global kmem (4K @ cpu0prvpage) */
 846         movl    R(cpu0pp), %eax
 847         movl    $1, %ecx
 848         fillkptphys($PG_RW)
 849
 850 /* Map SMP page table page into global kmem FWIW */
 851         movl    R(SMPptpa), %eax
 852         movl    $1, %ecx
 853         fillkptphys($PG_RW)
 854
 855 /* Map the private page into the SMP page table */
 856         movl    R(cpu0pp), %eax
 857         movl    $0, %ebx                /* pte offset = 0 */
 858         movl    $1, %ecx                /* one private page coming right up */
 859         fillkpt(R(SMPptpa), $PG_RW)
 860
 861 /* ... and put the page table table in the pde. */
 862         movl    R(SMPptpa), %eax
 863         movl    $MPPTDI, %ebx
 864         movl    $1, %ecx
 865         fillkpt(R(_IdlePTD), $PG_RW)
 866
 867 /* Fakeup VA for the local apic to allow early traps. */
 868         ALLOCPAGES(1)
 869         movl    %esi, %eax
 870         movl    $(NPTEPG-1), %ebx       /* pte offset = NTEPG-1 */
 871         movl    $1, %ecx                /* one private pt coming right up */
 872         fillkpt(R(SMPptpa), $PG_RW)
 873
 874 /* Initialize mp lock to allow early traps */
 875         movl    $1, R(_mp_lock)
 876 #endif  /* SMP */
 877
 878 /* install a pde for temporary double map of bottom of VA */
 879         movl    R(_KPTphys), %eax
 880         xorl    %ebx, %ebx
 881         movl    $NKPT, %ecx
 882         fillkpt(R(_IdlePTD), $PG_RW)
 883
 884 /* install pde's for pt's */
 885         movl    R(_KPTphys), %eax
 886         movl    $KPTDI, %ebx
 887         movl    $NKPT, %ecx
 888         fillkpt(R(_IdlePTD), $PG_RW)
 889
 890 /* install a pde recursively mapping page directory as a page table */
 891         movl    R(_IdlePTD), %eax
 892         movl    $PTDPTDI, %ebx
 893         movl    $1,%ecx
 894         fillkpt(R(_IdlePTD), $PG_RW)
 895
 896         ret
 897
 898 #ifdef BDE_DEBUGGER
 899 bdb_prepare_paging:
 900         cmpl    $0,R(_bdb_exists)
 901         je      bdb_prepare_paging_exit
 902
 903         subl    $6,%esp
 904
 905         /*
 906          * Copy and convert debugger entries from the bootstrap gdt and idt
 907          * to the kernel gdt and idt.  Everything is still in low memory.
 908          * Tracing continues to work after paging is enabled because the
 909          * low memory addresses remain valid until everything is relocated.
 910          * However, tracing through the setidt() that initializes the trace
 911          * trap will crash.
 912          */
 913         sgdt    (%esp)
 914         movl    2(%esp),%esi            /* base address of bootstrap gdt */
 915         movl    $R(_gdt),%edi
 916         movl    %edi,2(%esp)            /* prepare to load kernel gdt */
 917         movl    $8*18/4,%ecx
 918         cld
 919         rep                             /* copy gdt */
 920         movsl
 921         movl    $R(_gdt),-8+2(%edi)     /* adjust gdt self-ptr */
 922         movb    $0x92,-8+5(%edi)
 923         lgdt    (%esp)
 924
 925         sidt    (%esp)
 926         movl    2(%esp),%esi            /* base address of current idt */
 927         movl    8+4(%esi),%eax          /* convert dbg descriptor to ... */
 928         movw    8(%esi),%ax
 929         movl    %eax,R(bdb_dbg_ljmp+1)  /* ... immediate offset ... */
 930         movl    8+2(%esi),%eax
 931         movw    %ax,R(bdb_dbg_ljmp+5)   /* ... and selector for ljmp */
 932         movl    24+4(%esi),%eax         /* same for bpt descriptor */
 933         movw    24(%esi),%ax
 934         movl    %eax,R(bdb_bpt_ljmp+1)
 935         movl    24+2(%esi),%eax
 936         movw    %ax,R(bdb_bpt_ljmp+5)
 937         movl    R(_idt),%edi
 938         movl    %edi,2(%esp)            /* prepare to load kernel idt */
 939         movl    $8*4/4,%ecx
 940         cld
 941         rep                             /* copy idt */
 942         movsl
 943         lidt    (%esp)
 944
 945         addl    $6,%esp
 946
 947 bdb_prepare_paging_exit:
 948         ret
 949
 950 /* Relocate debugger gdt entries and gdt and idt pointers. */
 951 bdb_commit_paging:
 952         cmpl    $0,_bdb_exists
 953         je      bdb_commit_paging_exit
 954
 955         movl    $_gdt+8*9,%eax          /* adjust slots 9-17 */
 956         movl    $9,%ecx
 957 reloc_gdt:
 958         movb    $KERNBASE>>24,7(%eax)   /* top byte of base addresses, was 0, */
 959         addl    $8,%eax                 /* now KERNBASE>>24 */
 960         loop    reloc_gdt
 961
 962         subl    $6,%esp
 963         sgdt    (%esp)
 964         addl    $KERNBASE,2(%esp)
 965         lgdt    (%esp)
 966         sidt    (%esp)
 967         addl    $KERNBASE,2(%esp)
 968         lidt    (%esp)
 969         addl    $6,%esp
 970
 971         int     $3
 972
 973 bdb_commit_paging_exit:
 974         ret
 975
 976 #endif /* BDE_DEBUGGER */