contrib/gcc/config/alpha/crtend.asm

   1  # Copyright (C) 1996 Free Software Foundation, Inc.
   2  #  Contributed by Richard Henderson (rth@tamu.edu)
   3  #
   4  # This file is free software; you can redistribute it and/or modify it
   5  # under the terms of the GNU General Public License as published by the
   6  # Free Software Foundation; either version 2, or (at your option) any
   7  # later version.
   8  #
   9  # In addition to the permissions in the GNU General Public License, the
  10  # Free Software Foundation gives you unlimited permission to link the
  11  # compiled version of this file with other programs, and to distribute
  12  # those programs without any restriction coming from the use of this
  13  # file.  (The General Public License restrictions do apply in other
  14  # respects; for example, they cover modification of the file, and
  15  # distribution when not linked into another program.)
  16  #
  17  # This file is distributed in the hope that it will be useful, but
  18  # WITHOUT ANY WARRANTY; without even the implied warranty of
  19  # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20  # General Public License for more details.
  21  #
  22  # You should have received a copy of the GNU General Public License
  23  # along with this program; see the file COPYING.  If not, write to
  24  # the Free Software Foundation, 59 Temple Place - Suite 330,
  25  # Boston, MA 02111-1307, USA.
  26  #
  27  #    As a special exception, if you link this library with files
  28  #    compiled with GCC to produce an executable, this does not cause
  29  #    the resulting executable to be covered by the GNU General Public License.
  30  #    This exception does not however invalidate any other reasons why
  31  #    the executable file might be covered by the GNU General Public License.
  32
  33  #
  34  # Tails of the constructor/destructor lists.
  35  #
  36
  37  # The __*TOR_END__ symbols are not global because when this file is used
  38  # in a shared library, we do not want the symbol to fall over to the
  39  # application's lists.
  40
  41 .section .ctors,"aw"
  42
  43         .align 3
  44 __CTOR_END__:
  45         .quad   0
  46
  47 .section .dtors,"aw"
  48
  49         .align 3
  50 __DTOR_END__:
  51         .quad   0
  52
  53 .section .eh_frame,"aw"
  54 __FRAME_END__:
  55         .quad   0
  56
  57  #
  58  # Fragment of the ELF _init routine that invokes our ctor startup
  59  #
  60
  61 .section .init,"ax"
  62
  63         # Since the bits of the _init function are spread across many
  64         # object files, each potentially with its own GP, we must
  65         # assume we need to load ours.  Further, our .init section
  66         # can easily be more than 4MB away from our .text bits so we
  67         # can't use bsr.
  68
  69         br      $29,1f
  70 1:      ldgp    $29,0($29)
  71         jsr     $26,__do_global_ctors_aux
  72
  73         # Must match the alignment we got from crti.o else we get
  74         # zero-filled holes in our _init function and thense SIGILL.
  75         .align 3
  76
  77  #
  78  # Invoke our destructors in order.
  79  #
  80
  81 .text
  82
  83         .align 3
  84         .ent __do_global_ctors_aux
  85
  86 __do_global_ctors_aux:
  87         ldgp    $29,0($27)
  88         lda     $30,-16($30)
  89         .frame  $30,16,$26,0
  90         stq     $9,8($30)
  91         stq     $26,0($30)
  92         .mask   0x4000200,-16
  93         .prologue 1
  94
  95         lda     $9,__CTOR_END__
  96         br      1f
  97 0:      jsr     $26,($27)
  98 1:      ldq     $27,-8($9)
  99         subq    $9,8,$9
 100         not     $27,$0
 101         bne     $0,0b
 102
 103         ldq     $26,0($30)
 104         ldq     $9,8($30)
 105         lda     $30,16($30)
 106         ret
 107
 108         .end __do_global_ctors_aux