release/scripts/driver-remove.awk

   1 #!/usr/bin/awk -f
   2 #
   3 # Copyright (c) 2000  "HOSOKAWA, Tatsumi" <hosokawa@FreeBSD.org>
   4 # Copyright (c) 2002  Ruslan Ermilov <ru@FreeBSD.org>
   5 # All rights reserved.
   6 #
   7 # Redistribution and use in source and binary forms, with or without
   8 # modification, are permitted provided that the following conditions
   9 # are met:
  10 # 1. Redistributions of source code must retain the above copyright
  11 #    notice, this list of conditions and the following disclaimer.
  12 # 2. Redistributions in binary form must reproduce the above copyright
  13 #    notice, this list of conditions and the following disclaimer in the
  14 #    documentation and/or other materials provided with the distribution.
  15 #
  16 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  17 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  18 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  19 # ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  20 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  21 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  22 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  23 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  24 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  25 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  26 # SUCH DAMAGE.
  27 #
  28 # $FreeBSD: src/release/scripts/driver-remove.awk,v 1.2.2.1 2002/08/08 08:38:18 ru Exp $
  29 #
  30
  31 function usage()
  32 {
  33         print "usage: driver-remove.awk config_file BOOTMFS" > "/dev/stderr";
  34         exit 1;
  35 }
  36
  37 function err(eval, fmt, what)
  38 {
  39         printf "driver-remove.awk: " fmt "\n", what > "/dev/stderr";
  40         exit eval;
  41 }
  42
  43 function readconfig()
  44 {
  45         while ((r = (getline < config)) > 0) {
  46                 sub("#.*$", "");
  47                 if (sub(/^[[:alnum:]_]+[ \t]+[[:alnum:]_]+[ \t]+[0-9]+[ \t]+[[:alnum:]_]+[ \t]+\".*\"[ \t]*$/, "&")) {
  48                         sub(/[ \t]+/, "#");
  49                         sub(/[ \t]+/, "#");
  50                         sub(/[ \t]+/, "#");
  51                         sub(/[ \t]+/, "#");
  52                         sub(/\"/, "");
  53                         sub(/\"/, "");
  54                         split($0, arg, "#");
  55                         if (arg[4] == "options")
  56                                 options[arg[1]] = 1;
  57                         else
  58                                 drivers[arg[1]] = 1;
  59                 }
  60         }
  61         if (r == -1)
  62                 err(1, "error reading %s", config);
  63         close(config);
  64 }
  65
  66 BEGIN {
  67         if (ARGC != 3)
  68                 usage();
  69
  70         config = ARGV[1];
  71         bootmfs = ARGV[2];
  72
  73         readconfig();
  74
  75         lines = 0;
  76         while ((r = (getline < bootmfs)) > 0) {
  77                 if (/^device[ \t]+[[:alnum:]_]+/) {
  78                         dev = $0;
  79                         sub(/^device[ \t]+/, "", dev);
  80                         sub(/[ \t]+.*$/, "", dev);
  81                         if (dev in drivers)
  82                                 continue;
  83                 } else if (/^options[ \t]+[[:alnum:]_]+/) {
  84                         opt = $0;
  85                         sub(/^options[ \t]+/, "", opt);
  86                         sub(/[ \t]+.*$/, "", opt);
  87                         if (opt in options)
  88                                 continue;
  89                 }
  90                 line[lines++] = $0;
  91         }
  92         if (r == -1)
  93                 err(1, "error reading %s", bootmfs);
  94         close(bootmfs);
  95         printf "" > bootmfs;
  96         for (i = 0; i < lines; i++)
  97                 print line[i] >> bootmfs;
  98         close(bootmfs);
  99 }