sys/dev/misc/pccard/devlist2h.awk

   1 #! /usr/bin/awk -f
   2 #       $NetBSD: devlist2h.awk,v 1.3 1998/09/05 14:42:06 christos Exp $
   3 # $FreeBSD: src/sys/dev/pccard/devlist2h.awk,v 1.1 1999/10/26 06:52:28 imp Exp $
   4 #
   5 # Copyright (c) 1998 The NetBSD Foundation, Inc.
   6 # All rights reserved.
   7 #
   8 # This code is derived from software contributed to The NetBSD Foundation
   9 # by Christos Zoulas.
  10 #
  11 # Redistribution and use in source and binary forms, with or without
  12 # modification, are permitted provided that the following conditions
  13 # are met:
  14 # 1. Redistributions of source code must retain the above copyright
  15 #    notice, this list of conditions and the following disclaimer.
  16 # 2. Redistributions in binary form must reproduce the above copyright
  17 #    notice, this list of conditions and the following disclaimer in the
  18 #    documentation and/or other materials provided with the distribution.
  19 # 3. All advertising materials mentioning features or use of this software
  20 #    must display the following acknowledgement:
  21 #        This product includes software developed by the NetBSD
  22 #        Foundation, Inc. and its contributors.
  23 # 4. Neither the name of The NetBSD Foundation nor the names of its
  24 #    contributors may be used to endorse or promote products derived
  25 #    from this software without specific prior written permission.
  26 #
  27 # THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  28 # ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  29 # TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  30 # PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  31 # BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  32 # CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  33 # SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  34 # INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  35 # CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  36 # ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  37 # POSSIBILITY OF SUCH DAMAGE.
  38 #
  39 # Copyright (c) 1995, 1996 Christopher G. Demetriou
  40 # All rights reserved.
  41 #
  42 # Redistribution and use in source and binary forms, with or without
  43 # modification, are permitted provided that the following conditions
  44 # are met:
  45 # 1. Redistributions of source code must retain the above copyright
  46 #    notice, this list of conditions and the following disclaimer.
  47 # 2. Redistributions in binary form must reproduce the above copyright
  48 #    notice, this list of conditions and the following disclaimer in the
  49 #    documentation and/or other materials provided with the distribution.
  50 # 3. All advertising materials mentioning features or use of this software
  51 #    must display the following acknowledgement:
  52 #      This product includes software developed by Christopher G. Demetriou.
  53 #      This product includes software developed by Christos Zoulas
  54 # 4. The name of the author(s) may not be used to endorse or promote products
  55 #    derived from this software without specific prior written permission
  56 #
  57 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  58 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  59 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  60 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  61 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  62 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  63 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  64 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  65 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  66 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  67 #
  68 function collectline(f, line) {
  69         oparen = 0
  70         line = ""
  71         while (f <= NF) {
  72                 if ($f == "#") {
  73                         line = line "("
  74                         oparen = 1
  75                         f++
  76                         continue
  77                 }
  78                 if (oparen) {
  79                         line = line $f
  80                         if (f < NF)
  81                                 line = line " "
  82                         f++
  83                         continue
  84                 }
  85                 line = line $f
  86                 if (f < NF)
  87                         line = line " "
  88                 f++
  89         }
  90         if (oparen)
  91                 line = line ")"
  92         return line
  93 }
  94 BEGIN {
  95         nproducts = nvendors = 0
  96         dfile="pccarddevs_data.h"
  97         hfile="pccarddevs.h"
  98 }
  99 NR == 1 {
 100         VERSION = $0
 101         gsub("\\$", "", VERSION)
 102
 103         printf("/*\t\$FreeBSD\$\t*/\n\n") > dfile
 104         printf("/*\n") > dfile
 105         printf(" * THIS FILE AUTOMATICALLY GENERATED.  DO NOT EDIT.\n") \
 106             > dfile
 107         printf(" *\n") > dfile
 108         printf(" * generated from:\n") > dfile
 109         printf(" *\t%s\n", VERSION) > dfile
 110         printf(" */\n") > dfile
 111
 112         printf("/*\t\$FreeBSD\$\t*/\n\n") > hfile
 113         printf("/*\n") > hfile
 114         printf(" * THIS FILE AUTOMATICALLY GENERATED.  DO NOT EDIT.\n") \
 115             > hfile
 116         printf(" *\n") > hfile
 117         printf(" * generated from:\n") > hfile
 118         printf(" *\t%s\n", VERSION) > hfile
 119         printf(" */\n") > hfile
 120
 121         next
 122 }
 123 $1 == "vendor" {
 124         nvendors++
 125
 126         vendorindex[$2] = nvendors;             # record index for this name, for later.
 127         vendors[nvendors, 1] = $2;              # name
 128         vendors[nvendors, 2] = $3;              # id
 129         printf("#define\tPCCARD_VENDOR_%s\t%s\t", vendors[nvendors, 1],
 130             vendors[nvendors, 2]) > hfile
 131         vendors[nvendors, 3] = collectline(4, line)
 132         printf("/* %s */\n", vendors[nvendors, 3]) > hfile
 133         next
 134 }
 135 $1 == "product" {
 136         nproducts++
 137
 138         products[nproducts, 1] = $2;            # vendor name
 139         products[nproducts, 2] = $3;            # product id
 140         products[nproducts, 3] = $4;            # id
 141
 142         f = 5;
 143
 144         if ($4 == "{") {
 145                 products[nproducts, 3] = -1
 146                 z = "{ "
 147                 for (i = 0; i < 4; i++) {
 148                         if (f <= NF) {
 149                                 gsub("&sp", " ", $f)
 150                                 gsub("&tab", "\t", $f)
 151                                 gsub("&nl", "\n", $f)
 152                                 z = z $f " "
 153                                 f++
 154                         }
 155                         else {
 156                                 if (i == 3)
 157                                         z = z "NULL "
 158                                 else
 159                                         z = z "NULL, "
 160                         }
 161                 }
 162                 products[nproducts, 4] = z $f
 163                 f++
 164         }
 165         else {
 166                 products[nproducts, 4] = "{ NULL, NULL, NULL, NULL }"
 167         }
 168         printf("#define\tPCCARD_CIS_%s_%s\t%s\n",
 169             products[nproducts, 1], products[nproducts, 2],
 170             products[nproducts, 4]) > hfile
 171         printf("#define\tPCCARD_PRODUCT_%s_%s\t%s\n", products[nproducts, 1],
 172             products[nproducts, 2], products[nproducts, 3]) > hfile
 173
 174         products[nproducts, 5] = collectline(f, line)
 175
 176         printf("#define\tPCCARD_STR_%s_%s\t\"%s\"\n",
 177             products[nproducts, 1], products[nproducts, 2],
 178             products[nproducts, 5]) > hfile
 179
 180         next
 181 }
 182 {
 183         if ($0 == "")
 184                 blanklines++
 185         print $0 > hfile
 186         if (blanklines < 2)
 187                 print $0 > dfile
 188 }
 189 END {
 190         # print out the match tables
 191
 192         printf("\n") > dfile
 193
 194         printf("struct pccard_knowndev pccard_knowndevs[] = {\n") > dfile
 195         for (i = 1; i <= nproducts; i++) {
 196                 printf("\t{\n") > dfile
 197                 if (products[i, 3] == -1) {
 198                         printf("\t    PCCARD_VENDOR_UNKNOWN, PCCARD_PRODUCT_%s_%s,\n",
 199                             products[i, 1], products[i, 2]) > dfile
 200                 } else {
 201                         printf("\t    PCCARD_VENDOR_%s, PCCARD_PRODUCT_%s_%s,\n",
 202                             products[i, 1], products[i, 1], products[i, 2]) > dfile
 203                 }
 204                 printf("\t    PCCARD_CIS_%s_%s,\n",
 205                     products[i, 1], products[i, 2]) > dfile
 206                 printf("\t    ") > dfile
 207                 printf("0") > dfile
 208                 printf(",\n") > dfile
 209
 210                 vendi = vendorindex[products[i, 1]];
 211                 printf("\t    \"%s\",\n", vendors[vendi, 3]) > dfile
 212                 printf("\t    \"%s\"\t},\n", products[i, 5]) > dfile
 213                 printf("\t},\n") > dfile
 214         }
 215         for (i = 1; i <= nvendors; i++) {
 216                 printf("\t{\n") > dfile
 217                 printf("\t    PCCARD_VENDOR_%s, 0,\n", vendors[i, 1]) > dfile
 218                 printf("\t    PCCARD_KNOWNDEV_NOPROD,\n") > dfile
 219                 printf("\t    PCCARD_CIS_INVALID,\n") > dfile
 220                 printf("\t    \"%s\",\n", vendors[i, 3]) > dfile
 221                 printf("\t    NULL,\n") > dfile
 222                 printf("\t},\n") > dfile
 223         }
 224         printf("\t{ 0, 0, { NULL, NULL, NULL, NULL }, 0, NULL, NULL, }\n") > dfile
 225         printf("};\n") > dfile
 226 }